Conference vaxuum::document_ft

10.0. "BASELEVELS.COM" by CLOSET::ANKLAM () Fri Feb 20 1987 16:34

    Users who are installing T1.0 on systems with Base Level 6 and who
    want to keep both base levels active for a while can use the following
    command procedure. It will need some modification for each system,
    but overall will do the trick.
    
    The comments in this file describe the things the system manager
    must do to ensure that logical names, command synonyms, and so on
    are available for each base level correctly. The procedure assumes
    that existing users have specified @DOC$ROOT:[SETUP]DOC$SETUP in
    their LOGIN.COM files. This procedure illustrates a modified DOC$SETUP.
    
    
    $ save_verify := 'f$verify()$ if "''f$mode()'" .eqs. "BATCH" then set noverify
$ !
$ ! BASELEVEL.COM: Command file to 'toggle' baselevels
$ !
$ ! Use of this procedure assumes the following:
$ !
$ ! 1. VAX DOCUMENT T1.0 has been installed. All system-wide logical
$ !    name assignments are those for T1.0
$ !
$ ! 2. The following additional system-wide logical name assignments have
$ !    been made:
$ !
$ !    DOC$BL06_ROOT   - device on which Base Level 6 is installed
$ !    DOC$BL07_ROOT   - device on which T1.0 is installed
$ !    DOC$BASELEVELS  - device and directory containing BASELEVELS.COM
$ !
$ ! 3. The file DOC$BL07_ROOT:[SETUP]DOC$SETUP contains:
$ !
$ !    $ BASELEVEL :== @DOC$BASELEVELS:BASELEVEL
$ !    $ BASELEVEL 6 'p1' 'p2' 'p3' 'p4' 'p5' 'p6' 'p7'
$ !    $ EXIT
$ ! 
$ ! 4. The following files have been added to the BL06 [DOCTOOLS] tree
$ !    from the SYS$SHARE directory (these will be present if Base Level 6
$ !    was previously installed on the system):
$ !
$ !   SYS$SHARE:DOC$TEXSHR.EXE      --->  DOC$BL06_ROOT:[TOOLS]DOC$TEXSHR.EXE 
$ !   SYS$SHARE:DOC$GUTENTAGSHR.EXE --->  DOC$BL06_ROOT:[TOOLS]GUTENTAGSHR.EXE
$ !
$ !    (they are pointed to by the logical names DOC$TEXSHR and 
$ !    DOC$GUTENTAGSHR so the BL06 DOCUMENT command won't look in 
$ !    the system area. the files in the system area can be deleted.)
$ !  
$ !   TMAKEBOOK requires that you copy:
$ !
$ !   {CLOSET,VAXUUM}::KITS_:[DOCUMENT]TMAKEBOOK.COM
$ !   _to:  DOC$BL06_ROOT:[TEX.TOOLS]TMAKEBOOK.COM
$ !
$ !   This has slight modifications to work with the DOCUMENT command on
$ !   T1.0. 
$ !
$ ! Below, you can search for lines containing or preceded with:
$ !
$ !      !*****LOCAL
$ !
$ ! This indicates a place where base level 6 logicals and command synonyms
$ ! are defined and deassigned, and where base level 7 (T1.0) logicals
$ ! are assigned and deassigned. The actual commands, queue names, and on
$ ! may need modification for your own system.
$ !
$ ! All that's required is for users to enter:
$ !
$ ! $ baselevel {6|7}
$ !
$ ! Note that batch jobs get what's set in a user's LOGIN.COM file.
$ !====================================================================
$ delete := delete
$ goto := goto
$ write := write
$ define := define
$ !
$ BRANCH_ON_P1:
$ if (p1 .eqs. "SHOW") then goto SHOW_BASELEVEL
$ if (p1 .eqs. "SEVEN") .or. (p1 .eqs "7") then goto 7SETUP
$ if (p1 .eqs. "SIX") .or. (p1 .eqs "6") then goto 6SETUP
$ !
$ INQUIRE/NOPUNC P1 "What baselevel do you want to use (6/7)?"
$ GOTO BRANCH_ON_P1
$ !
$ 7SETUP:
$ !
$ if "''doc$$baselevel'" .eqs. "" then goto 7SETUP_NOT_ANYTHING !symbol not
$                                                                   ! defined
$ if doc$$baselevel .nes. "7" then goto 7SETUP_NOT_SEVEN
$ write sys$output "Staying at BL07"
$ GOTO ALL_DONE
$ !
$ 7SETUP_NOT_SEVEN:
$ !
$ if doc$$baselevel .nes. "6" then goto 7SETUP_NOT_SIX
$ write sys$output "Switching from BL06 to BL07"
$ next_action = "seven_on"
$ goto SIX_OFF
$ !
$ 7SETUP_NOT_SIX:
$ !                                                                        
$ if doc$$baselevel .nes. "DEVEL" then goto  7SETUP_NOT_ANYTHING
$ write sys$output "Switching from DEVEL to BL07"
$ next_action = "seven_on"
$ goto DEVEL_OFF
$ !
$ 7SETUP_NOT_ANYTHING:
$ !
$ write sys$output -
"Welcome to the multi-baselevel world of VAX DOCUMENT on 
$ write sys$output -
"         CLOSET/VAXUUM..." !*****LOCAL: your node/cluster name
$ goto SEVEN_ON
$ !
$ 6SETUP:
$ !
$ if "''doc$$baselevel'" .eqs. "" then goto 6SETUP_NOT_ANYTHING !symbol not
$                                                                   ! defined
$ if doc$$baselevel .nes. "6" then goto 6SETUP_NOT_SIX
$ write sys$output "Staying at BL06"
$ GOTO ALL_DONE
$ !
$ 6SETUP_NOT_SIX:
$ !
$ if doc$$baselevel .nes. "7" then goto 6SETUP_NOT_SEVEN
$ write sys$output "Switching from BL07 to BL06"
$ next_action = "six_on"
$ goto SEVEN_OFF
$ !
$ 6SETUP_NOT_SEVEN:
$ !
$ if doc$$baselevel .nes. "DEVEL" then goto  6SETUP_NOT_ANYTHING
$ write sys$output "Switching from DEVEL to BL06"
$ next_action = "six_on"
$ goto DEVEL_OFF
$ !
$ 6SETUP_NOT_ANYTHING:
$ !
$ write sys$output -
"Welcome to the multi-baselevel world of VAX DOCUMENT on CLOSET/VAXUUM..."
$ goto SIX_ON
$ !
$ SEVEN_ON:
$ WRITE SYS$OUTPUT "Defining logicals for VAX DOCUMENT T1.0-001... "
$ DOC$$BASELEVEL :== 7
$ DEFINE/NOLOG/EXEC/JOB DOC$ROOT DOC$BL07_ROOT
$ !
$ DEFINE/NOLOG DOC$LN03_FONTS DOC$BL07_ROOT:[TEX.LN03.FONTS]
$ DEFINE/NOLOG DVC$LN03SHR DOC$BL07_ROOT:[TEX.LN03.TOOLS]DVC$LN03SHR.EXE
$ !
$ DEFINE/NOLOG DOC$LPR_FONTS DOC$BL07_ROOT:[TEX.LPR.FONTS]
$ DEFINE/NOLOG DVC$LPRSHR DOC$BL07_ROOT:[TEX.LPR.TOOLS]DVC$LPRSHR.EXE
$ !
$ DEFINE/NOLOG DOC$PS_FONTS DOC$BL07_ROOT:[TEX.POSTSCRIPT.FONTS]
$ DEFINE/NOLOG DVC$PSSHR DOC$BL07_ROOT:[TEX.POSTSCRIPT.TOOLS]DVC$PSSHR.EXE
$ !
$ DEFINE/NOLOG DOC$STANDARD_FORMATS DOC$BL07_ROOT:[TEX.FORMATS]
$ !
$ DEFINE/NOLOG DOC$GUTENTAGSHR DOC$BL07_ROOT:[TOOLS]GUTENTAGSHR.EXE
$ DEFINE/NOLOG DOC$TEXSHR DOC$BL07_ROOT:[TOOLS]DOC$TEXSHR.EXE
$ DEFINE/NOLOG DOC$INDEXSHR DOC$BL07_ROOT:[TOOLS]DOC$INDEXSHR.EXE
$ ! Logical name for local formats and Local Elements
$ !
$ !  Local formats, elements, strings !*****LOCAL
$ DEFINE/NOLOG DOC$LOCAL_FORMATS DOC$BL07_ROOT:[LOCAL.FORMATS]
$ DEFINE/NOLOG DOC$LOCAL_ELEMENTS DOC$LOCAL_FORMATS:CUP$LOCAL_ELEMENTS.TEX
$ !
$ ! Logical name for local text strings for Tag Post-Translation !*****LOCAL
$ !
$  DEFINE   TAG$$LOCAL_STRINGS    DOC$LOCAL_FORMATS:CUP$LOCAL_STRINGS.TXT
$ !  DEASS TAG$$LOCAL_STRINGS
$ !
$ ! Logical name for local tools
$ !
$ DEFINE/NOLOG DOC$LOCAL_TOOLS DOC$BL07_ROOT:[LOCAL.TOOLS]
$ !
$ DEFINE/NOLOG DOC$LN01_FONTS DOC$BL07_ROOT:[TEX.LN01.FONTS]
$ DEFINE/NOLOG DOC$LN01_TOOLS DOC$BL07_ROOT:[TEX.LN01.TOOLS]
$ !
$ SDMLLSE	:==	LSEDIT/ENV=DOC$BL07_ROOT:[tools]SDMLLSE.ENV
$ !
$ WRITE SYS$OUTPUT "...Logicals for VAX DOCUMENT T1.0-001 defined"
$ !
$ GOTO ALL_DONE
$ !
$ SEVEN_OFF:
$ !
$ WRITE SYS$OUTPUT "Turning off logicals for VAX DOCUMENT T1.0-001..."
$ !
$ DELETE/SYMBOL/GLOBAL DOC$$BASELEVEL
$ DEASS/EXEC/JOB DOC$ROOT
$ !
$ DEASSIGN DOC$LN03_FONTS 
$ DEASSIGN DVC$LN03SHR
$ !
$ DEASSIGN DOC$LPR_FONTS
$ DEASSIGN DVC$LPRSHR 
$ !
$ DEASSIGN DOC$PS_FONTS
$ DEASSIGN DVC$PSSHR 
$ !
$ DEASSIGN DOC$STANDARD_FORMATS 
$ !
$ DEASSIGN DOC$GUTENTAGSHR 
$ DEASSIGN DOC$TEXSHR 
$ DEASSIGN DOC$INDEXSHR
$ !
$ DELETE/SYMBOL/GLOBAL SDMLLSE
$ !
$ WRITE SYS$OUTPUT "...Logicals for VAX DOCUMENT T1.0-001 deassigned"
$ !
$ GOTO 'NEXT_ACTION'
$ !
$ SIX_ON:
$ !
$ WRITE SYS$OUTPUT -
    " Defining logicals and symbols for VAX DOCUMENT Base Level 06... "
$ DOC$$BASELEVEL :== 6
$ DEFINE/NOLOG/EXEC/JOB DOC$ROOT DOC$BL06_ROOT
$ !
$!
$!<*-=-=-=-=-=-=-=-=-**!
$!** PARSE ARGUMENTS **!
$!**-=-=-=-=-=-=-=-=-*>!
$!
$ doc$$administrator == 0
$ doc$$tex_wizard == 0
$!
$ args = f$edit("''p1' ''p2' ''p3' ''p4' ''p5' ''p6' ''p7'","lowercase")
$ not_there = f$length(args)
$!
$ if (f$locate("administrator",args) .nes. not_there) then -
   doc$$administrator == 1
$ if (f$locate("tex_wizard",args) .nes. not_there) then -
   doc$$tex_wizard == 1
$!
$!<*-=-=-=-=-=-=-=-**!
$!** LOGICAL NAMES **!
$!**-=-=-=-=-=-=-=-*>!
$!
$ DEFINE/NOLOG DOC$GUTENTAGSHR DOC$BL06_ROOT:[TOOLS]GUTENTAGSHR.EXE
$ DEFINE/NOLOG DOC$TEXSHR DOC$BL06_ROOT:[TOOLS]DOC$TEXSHR.EXE
$ !
$ define = "define/nolog"
$!
$!** System-Dependent Logical Names
$!
$ define	DOC$LOCAL		DOC$BL06_ROOT:[LOCAL]
$ define	DOC$LSE			DOC$BL06_ROOT:[LSE]
$ define	DOC$SDML		DOC$BL06_ROOT:[SDML]
$ define	DOC$TEST_FILES		DOC$BL06_ROOT:[TESTFILES]
$ define 	DOC$TOOLS		DOC$BL06_ROOT:[TOOLS]
$!
$!** TeX Output Logical Names
$!
$ define	DOC$STANDARD_FORMATS	DOC$BL06_ROOT:[TEX.FORMATS]
$ define	DOC$TEX_TOOLS		DOC$BL06_ROOT:[TEX.TOOLS]
$ define	TEX$FORMATS		DOC$BL06_ROOT:[TEX.FMTFILES]
$!
$ define	DOC$TEX_TEMPLATES	DOC$BL06_ROOT:[TEX.TEMPLATES]
$ define	TEX$INPUTS		DOC$BL06_ROOT:[TEX.INPUTS]
$!
$!** Logical Names For Various Destinations
$!
$ define	DOC$LN01_FONTS		DOC$BL06_ROOT:[TEX.LN01.FONTS]
$ define	DOC$LN01_TOOLS		DOC$BL06_ROOT:[TEX.LN01.TOOLS]
$!
$ define	DOC$LN03_FONTS		DOC$BL06_ROOT:[TEX.LN03.FONTS]
$ define	DOC$LN03_TOOLS		DOC$BL06_ROOT:[TEX.LN03.TOOLS]
$!
$ define	DOC$LPR_FONTS		DOC$BL06_ROOT:[TEX.LPR.FONTS]
$ define	DOC$LPR_TOOLS		DOC$BL06_ROOT:[TEX.LPR.TOOLS]
$!
$ define	DOC$PS_FONTS		DOC$BL06_ROOT:[TEX.POSTSCRIPT.FONTS]
$ define	DOC$PS_TOOLS		DOC$BL06_ROOT:[TEX.POSTSCRIPT.TOOLS]
$!
$!<*-=-=-=-=-=-=-=-=-**!
$!** COMMAND SYMBOLS **!
$!**-=-=-=-=-=-=-=-=-*>!
$!
$!** Define command symbols for all system users.
$!
$ BATDOC	:==	@DOC$TEX_TOOLS:BATDOC    ! Runs DOCUMENT in batch.
$ BUILD_STT	:==	@DOC$TEX_TOOLS:BUILD_STT ! Create saved tag table file.
$ DSRGNC	:==	@DOC$TOOLS:DSRGNC
$ LN01SET	:==	@DOC$BL06_ROOT:[LOCAL.TOOLS]LN01SET
$ LN03SET	:==	@DOC$BL06_ROOT:[LOCAL.TOOLS]LN03SET
$ LPSET		:==	@DOC$BL06_ROOT:[LOCAL.TOOLS]LPSET
$ MAILSET	:==	@DOC$BL06_ROOT:[LOCAL.TOOLS]MAILSET
$ MAKEDLG	:==	@DOC$TOOLS:MAKEDLG
$ MAKESDF	:==	@DOC$TOOLS:MAKESDF
$ NEWDOC	:==	@DOC$TEX_TOOLS:NEWDOC
$ REPEAT	:==	@DOC$TOOLS:REPEAT
$ SDMLINFO 	:==	TYPE DOC$SDML:SDMLINFO.DAT
$ SDMLLSE	:==	LSEDIT/ENV=DOC$LSE:SDML.ENV
$ TERMSET	:==	@DOC$BL06_ROOT:[LOCAL.TOOLS]TERMSET
$ TMAKEBOOK	:==	@DOC$TEX_TOOLS:TMAKEBOOK
$ TMAKELIST	:==	@DOC$TEX_TOOLS:TMAKELIST
$ TRUN		:==	@DOC$TEX_TOOLS:TRUN
$!
$!** Command symbols for system administrators.
$!
$ if (doc$$administrator .eq. 0) then goto SYMBOLS_PAST_ADMINISTRATOR
$!
$ EGDX 		:==	@DOC$TEX_TOOLS:EDITGDX
$ FINDTAG	:==	@DOC$TEX_TOOLS:FINDTAG
$ FIXGDX	:==	@DOC$TEX_TOOLS:FIXGDX
$!
$SYMBOLS_PAST_ADMINISTRATOR:
$!
$!** Command symbols for TeX wizards.
$!
$ if (doc$$tex_wizard .eq. 0) then goto SYMBOLS_PAST_TEX_WIZARD
$!
$ DVITYP*E	:==	$DOC$TEX_TOOLS:DVITYPE
$ INITEX	:== 	$DOC$TEX_TOOLS:INITEX
$ PLTOTF	:==	$DOC$TEX_TOOLS:PLTOTF
$ TANGLE	:==	$DOC$TEX_TOOLS:TANGLE
$ TFTOPL	:==	$DOC$TEX_TOOLS:TFTOPL
$ WEAVE		:==	$DOC$TEX_TOOLS:WEAVE
$!
$SYMBOLS_PAST_TEX_WIZARD:
$!
$!<*-=-=-=-=-=-=-**!
$!** LOCAL SETUP **!
$!**-=-=-=-=-=-=-*>!
$!
$ ! Queue Names
$ ! -----------
$ ! Print queue for LN01 jobs
$ DEFINE DOC$LN01_QUEUE LN01$PRINT !*****LOCAL Base level 6 LN01 queue
$ !
$ ! Print queue for LN03 jobs
$ DEFINE DOC$LN03_QUEUE LN03$PRINT !*****LOCAL Base level 6 LN03 queue
$ !
$ ! Batch queue for single-file SDML jobs
$ DEFINE DOC$BATCH_QUEUE SYS$BATCH !*****LOCAL Base level 6 batch queue
$ !
$ ! Batch queue for book builds
$ DEFINE DOC$BOOKBUILD_QUEUE SYS$BATCH !*****LOCAL Base level 6 bookbuild queu
$ !
$ ! Logical name for local formats and Local Elements -- Base Level 6
$ !
$ DEFINE   DOC$LOCAL_FORMATS     DOC$BL06_ROOT:[LOCAL.FORMATS] !*****LOCAL 
$ DEFINE   DOC$LOCAL_ELEMENTS    DOC$LOCAL_FORMATS:LOCAL_ELEMENTS.TEX !****LOCAL
$ !
$ ! Logical name for local text strings for Tag Post-Translation
$ !
$ DEFINE   TAG$$LOCAL_STRINGS    DOC$LOCAL_FORMATS:LOCAL_STRINGS.TXT
$ !
$ ! Logical name for local tools
$ !
$ DEFINE   DOC$LOCAL_TOOLS     DOC$BL06_ROOT:[LOCAL.TOOLS]
$ !
$ ! Symbols to run M. Etzel's procedures 
$ !
$ MAKEBOOKLIST :== @DOC$LOCAL_TOOLS:MAKEBOOKLIST.COM
$ MENUDOC      :== @DOC$LOCAL_TOOLS:MENUDOC.COM
$ MENUDOC_RUN  :== SET HOST NEWDOC
$ !
$ ! Logical name for local templates
$ !
$  DEFINE   DOC$LOCAL_TEMPLATES     DOC$BL06_ROOT:[LOCAL.TEMPLATES]
$ ! 
$ ! Local tool definitions
$ !
$ DOC$CONVERT :== $DOC$BL07_ROOT:[LOCAL.TOOLS]DOC$CONVERT_06_FILES
$!*****LOCAL. Here put any local symbol names from your previous
$!*****version of DOC$LOCAL_SETUP. Put Bl6 names here.
$!
$!<*-=-=-=-=-=-=-=-=-=-=-=**!
$!** TYPE WELCOME MESSAGE **!
$!**-=-=-=-=-=-=-=-=-=-=-=*>!
$!
$ if (f$search("DOC$BL06_ROOT:[SETUP]SDML_WELCOME.TXT") .nes. "") then -
   type DOC$BL06_ROOT:[SETUP]SDML_WELCOME.TXT
$ !
$ WRITE SYS$OUTPUT "...Logical names and symbols for VAX DOCUMENT BL06 defined"
$ !
$ GOTO ALL_DONE
$ !
$ SIX_OFF:
$ !
$ WRITE SYS$OUTPUT -
    " Deassigning logicals and symbols for VAX DOCUMENT Base Level 06... "
$ DELETE/SYMBOL/GLOBAL DOC$$BASELEVEL
$ DEASSIGN/EXEC/JOB DOC$ROOT
$!
$!** System-Dependent Logical Names
$!
$ DEASSIGN DOC$GUTENTAGSHR 
$ DEASSIGN DOC$TEXSHR 
$ !
$ deassign DOC$LOCAL
$ deassign DOC$LSE	
$ deassign DOC$SDML
$ deassign DOC$TEST_FILES
$ deassign DOC$TOOLS
$!
$!** TeX Output Logical Names
$!
$ deassign DOC$STANDARD_FORMATS
$ deassign DOC$TEX_TOOLS
$ deassign TEX$FORMATS
$!
$ deassign DOC$TEX_TEMPLATES
$ deassign TEX$INPUTS
$!
$!** Logical Names For Various Destinations
$!
$ deassign DOC$LN01_FONTS 
$ deassign DOC$LN01_TOOLS 
$!
$ deassign DOC$LN03_FONTS
$ deassign DOC$LN03_TOOLS
$!
$ deassign DOC$LPR_FONTS
$ deassign DOC$LPR_TOOLS
$!
$ deassign DOC$PS_FONTS
$ deassign DOC$PS_TOOLS
$!
$!<*-=-=-=-=-=-=-=-=-**!
$!** COMMAND SYMBOLS **!
$!**-=-=-=-=-=-=-=-=-*>!
$!
$!** Define command symbols for all system users.
$!
$ DELETE/SYMBOL/GLOBAL BATDOC
$ DELETE/SYMBOL/GLOBAL BUILD_STT
$ DELETE/SYMBOL/GLOBAL DSRGNC
$ DELETE/SYMBOL/GLOBAL LN01SET
$ DELETE/SYMBOL/GLOBAL LN03SET
$ DELETE/SYMBOL/GLOBAL LPSET	
$ DELETE/SYMBOL/GLOBAL MAILSET
$ DELETE/SYMBOL/GLOBAL MAKEDLG
$ DELETE/SYMBOL/GLOBAL MAKESDF
$ DELETE/SYMBOL/GLOBAL NEWDOC
$ DELETE/SYMBOL/GLOBAL REPEAT
$ DELETE/SYMBOL/GLOBAL SDMLINFO 
$ DELETE/SYMBOL/GLOBAL SDMLLSE
$ DELETE/SYMBOL/GLOBAL TERMSET
$ DELETE/SYMBOL/GLOBAL TMAKEBOOK
$ DELETE/SYMBOL/GLOBAL TMAKELIST
$ DELETE/SYMBOL/GLOBAL TRUN	
$!
$!** Command symbols for system administrators.
$!
$ if (doc$$administrator .eq. 0) then goto DELETE_SYMBOLS_PAST_ADMINISTRATOR
$!
$ DELETE/SYMBOL/GLOBAL EGDX 	
$ DELETE/SYMBOL/GLOBAL FINDTAG
$ DELETE/SYMBOL/GLOBAL FIXGDX
$!
$ DELETE_SYMBOLS_PAST_ADMINISTRATOR:
$!
$!** Command symbols for TeX wizards.
$!
$ if (doc$$tex_wizard .eq. 0) then goto DELETE_SYMBOLS_PAST_TEX_WIZARD
$!
$ DELETE/SYMBOL/GLOBAL DVITYPE
$ DELETE/SYMBOL/GLOBAL INITEX
$ DELETE/SYMBOL/GLOBAL PLTOTF
$ DELETE/SYMBOL/GLOBAL TANGLE
$ DELETE/SYMBOL/GLOBAL TFTOPL
$ DELETE/SYMBOL/GLOBAL WEAVE	
$!
$ DELETE_SYMBOLS_PAST_TEX_WIZARD:
$ !
$!
$!<*-=-=-=-=-=-=-**!
$!** LOCAL SETUP **!
$!**-=-=-=-=-=-=-*>!
$!
$ ! Queue Names
$ ! -----------
$ ! Print queue for LN01 jobs
$ DEASSIGN DOC$LN01_QUEUE !*****LOCAL Base level 6 LN01 queue
$ !
$ ! Print queue for LN03 jobs
$ DEASSIGN DOC$LN03_QUEUE !*****LOCAL Base level 6 LN03 queue
$ !
$ ! Batch queue for single-file SDML jobs
$ DEASSIGN DOC$BATCH_QUEUE !*****LOCAL Base level 6 queue
$ !
$ ! Batch queue for book builds
$ DEASSIGN DOC$BOOKBUILD_QUEUE !*****LOCAL Base level 6queue
$ !
$ !
$ ! Logical name for local templates
$ !
$  DEASSIGN   DOC$LOCAL_TEMPLATES 
$ !
$ !
$ ! Local tool definitions
$!*****LOCAL. delete baselevel 6 synonyms here:
$ !
$! delete/symbol/global symbol-name
$ !
$ WRITE SYS$OUTPUT "...Logical names and symbols for VAX DOCUMENT BL06 deassigned"
$ !
$ GOTO 'NEXT_ACTION'
$ !
$ SHOW_BASELEVEL:
$ WRITE SYS$OUTPUT "You are using base level ''doc$$baselevel'"
$ GOTO ALL_DONE
$ !
$ ALL_DONE:
$ EXIT
$ !
$ if "''f$mode()'" .eqs. "BATCH" then set verify

    This procedure looks a bit different from the one you gave out to
    pre-t1 sites. Improved?
    

    
    Yes, I added comments in places where site-specific things should
    be looked at. Also, more comments at the beginning. (Todd Little
    helped much with this!)

    what's the trick to run batdoc from doc$bl06_root:[tex.tools] ?
    After switching back to bs lvl 06, (with baselevel) batdoc is 
    recognized as a symbol
    for T1.0... which it goes and gets from doc$baselevels. The log
    file reads as if I requested T1.0...
    
    thanks,
    Bette Jean

    
    your LOGIN.COM must specify that you are running baselevel 6.
    
    pa