Conference vaxuum::online_bookbuilding

193.0. "New, improved cure for tunnel vision" by REORG::ROGOFF (Zen Software Documentation) Wed Sep 06 1989 15:45

Most writers of online books want to be able to build, view, and debug
their work in private. At the same time, they want access to their
system's public online documentation library. 

It's not difficult to make the Version 1 Bookreader see files in your
private directories as well as those in your system's public library.
You don't need any special privileges and you don't have to modify the
public library directories in any way. Here's how to do it: 

1. If you have commands in your LOGIN.COM or elsewhere that define the
   logical name DECW$BOOK, get rid of them. You won't need them any
   more and they may obscure the logical name that is created when
   DECwindows starts up.

2. Notes> EXTRACT/NOHEAD SYS$LOGIN:BOOKREADER.COM .1

3. Notes> EXTRACT/NOHEAD SYS$LOGIN:LIBRARY.DECW$BOOKSHELF .2

4. Exit Notes and create a personal bookshelf file.

	$ EDIT/TPU/CREATE SYS$LOGIN:PERSONAL.DECW$BOOKSHELF

   Insert as many private book or shelf lines as you need. The syntax
   is: 

	shelf\filespec\title
	book\filespec\title

5. To run the Bookreader from DCL, invoke (@) the command procedure.

	$ @SYS$LOGIN:BOOKREADER

   If you invoke the command procedure on a remote system, it attempts
   to open the display on your local system. In other words, it tries
   to run in client/server mode. 

   To run the Bookreader from a FileView window,

	a. Pull down the "Customize" menu and select "Verbs and Menus".

	b. In the leftmost column (Verb Names) select "Bookreader".

	c. In the "DCL Command for Selected Verb" field, change the
           command to: 

		@SYS$LOGIN:BOOKREADER.COM 

	d. OK the customization.

	e. Pull down the "Customize" menu and select "Save Startup View".

	f. Pull down the "Applications" menu and select "Bookreader".

$ !
$ ! BOOKREADER.COM (for V1 Bookreader)
$ !
$ ! Specify the name of the directory that contains your own
$ ! LIBRARY.DECW$BOOKSHELF and PERSONAL$DECW$BOOKSHELF files.
$ !
$ dir_name = f$trnlnm("sys$login")
$ !
$ ! Your LIBRARY.DECW$BOOKSHELF file must contain the following two
$ ! "shelf" entries:
$ !
$ !	shelf\public$library\Public Library
$ !	shelf\personal$library\Personal Library
$ !
$ ! Your PERSONAL.DECW$BOOKSHELF file contains "shelf" and "book"
$ ! entries for your personal online documentation. For example:
$ !
$ !	book\sql$disk:[rogoff.fiction]gwtw.decw$book\Gone With the Wind
$ !
$ ! If running on remote node, open display on local node
$ !
$ node_name = f$trnlm("sys$rem_node")
$ if node_name .nes. "" then set display/create/node='node_name'
$ !
$ ! Define logical names for bookshelves
$ !
$ define := define/user
$ define public$library 'f$search("decw$book:library.decw$bookshelf")'
$ define personal$library 'dir_name'personal.decw$bookshelf
$ !
$ ! Translate DECW$BOOK and append to personal directory name
$ !
$ set noon
$ index = 0
$ max_index = f$trnlnm("decw$book","decw$logical_names",,,,"max_index")
$loop:
$ dir_name = dir_name + "," + f$trnlnm("decw$book","decw$logical_names",index)
$ index = index + 1
$ if index .le. max_index then goto loop
$ !
$ ! Redefine DECW$BOOK as new search string
$ !
$ define decw$book 'dir_name'
$ !
$ ! Do appropriate stuff for FileView 
$ !
$ if f$mode() .nes. "INTERACTIVE"
$   then
$	vue$popup_progress_box 8
$	vue$suppress_output_popup
$ endif
$ !
$ run sys$system:decw$bookreader
$ if node_name .nes. "" then set display/noperm

shelf\public$library\Public Library
shelf\personal$library\Personal Library