Conference ilbbak::ibi_focus

562.0. "Problem with CRTFORM" by MLNAD0::FERRARIF () Mon Oct 25 1993 09:55

	Hi all,

	Running an Application using FOCUS and I got the following problem:
	the screen, created with -CRTFORM, is not completely displayed,
	but only the INPUT/OUTPUT fields are shown.
	All the descriptions and heading are not on the screen as they should.

	The same procedure worked fine till last month, and is now working
	correctly on another machine.

	No change of release was done, no upgrade.
	We are running 6.1.0.
	Here follows the procedure giving the problem. (it is not the only
	one).

        Thanks in advance for any help or suggestion.
	Fabio.
	MLNAD0::FERRARIF
	7793-2564

-***************************************************************************-
-***************************************************************************-
-*
-*    System        :     Sport
-*    Procedure     :     Ita_07_r.fex
-*    Author        :     Fabio Ferrari
-*    Data          :     20-01-93
-*    Description   :     Option Status and Installed Base List
-*    Output        :     File Sport$$d_lwrk:ita_07.wrk
-*
-*    Modifications Log
-*    Author     Data       Notes
-*    -          -          -
-*
-***************************************************************************-
-***************************************************************************-
-**
EXEC SPORT$$D_EXE:FOC_SET
-RUN
-**
-************************************************************
-* File Definition Offline
-************************************************************
-**
-VMS STATE SPORT$$D_LWRK:ITA_07.PAR
-RUN
-IF &RETCODE NE  0 THEN GOTO SPORT5;
-RUN
-**
FI OFFLINE CLEAR
FI OFFLINE DISK SPORT$$D_LWRK:ITA_07.WRK
-**
-************************************************************
-*  Definition Of The Relations
-************************************************************
-**
FI  GPSP14    DISK SPORT$$F_SPACEDB
FI  CO_LO_KI DISK SPORT$$F_SPACEDB
FI  LOKISP14 DISK SPORT$$F_SPACEDB
-*
FI  EN_SP14    DISK SPORT$$F_SPACEDB
FI  EN_OS    DISK SPORT$$F_SPACEDB
FI  EN_SL    DISK SPORT$$F_SPACEDB
FI  EN_KO    DISK SPORT$$F_SPACEDB
FI  EN_GP    DISK SPORT$$F_SPACEDB
FI  EN_KI    DISK SPORT$$F_SPACEDB
FI  EN_CO_LO DISK SPORT$$F_SPACEDB
-RUN
-*******************************************
-* Set Up Date For Control
-*******************************************
-**
-SET  &DD=EDIT(&DATE,'$$$99$$$');
-SET  &MM=EDIT(&DATE,'99$$$$$$');
-SET  &YY=EDIT(&DATE,'$$$$$$99');
-SET  &OUJ=&YY||&MM||ⅅ
-*
-SET  &MESE=DECODE  &MM (01 'JAN'
-                         02 'FEB'
-                         03 'MAR'
-                         04 'APR'
-                         05 'MAY'
-                         06 'JUN'
-                         07 'JUL'
-                         08 'AUG'
-                         09 'SEP'
-                         10 'OCT'
-                         11 'NOV'
-                         12 'DEC');
-SET &OGGI=&DD||'-'||&MESE||'-'||&YY;
-RUN
-*
-*******************************************
-*       Definition Of Parameters File
-*******************************************
-**
FI PARA DISK SPORT$$D_LWRK:ITA_07.PAR
-RUN
-**
-SET  &&DD=EDIT(&DATE,'$$$99$$$');
-SET  &&MM=EDIT(&DATE,'99$$$$$$');
-SET  &&YY=EDIT(&DATE,'$$$$$$99');
-RUN
-**
-SET  &&MESE=DECODE  &&MM (01 'JAN'
-                         02 'FEB'
-                         03 'MAR'
-                         04 'APR'
-                         05 'MAY'
-                         06 'JUN'
-                         07 'JUL'
-                         08 'AUG'
-                         09 'SEP'
-                         10 'OCT'
-                         11 'NOV'
-                         12 'DEC');
-RUN
-SET &TODAY=&&DD||'-'||&&MESE||'-'||&&YY;
-RUN
-**
-***************************************************************
-*              Read Parameters File
-***************************************************************
-**
-**
-READ PARA &COMPANY.A30 &SERCC.A6 &ORDSORT.A4 &VUO.A2.
-RUN
-*
-SET &EMPTY= IF &VUO EQ 'SI' THEN
-          'Nessuna selezione: Viene assunto il Sort di Default.'
-                            ELSE ' ';
-**
-TYPE Parametri selezionati
-TYPE
-TYPE Company : &COMPANY
-TYPE Cost centre : &SERCC
-TYPE
-**
-SET &S1 = EDIT (&ORDSORT,'9$$$');
-SET &SORT1=IF &S1 EQ 0 THEN ' ' ELSE
-             IF &S1 EQ 1 THEN 'Badge Admin' ELSE
-               IF &S1 EQ 2 THEN 'Badge Sales' ELSE
-                 IF &S1 EQ 3 THEN 'Srvc CC' ELSE 'Company Name';
-*
-SET &S2 = EDIT (&ORDSORT,'$9$$');
-SET &SORT2=IF &S2 EQ 0 THEN ' ' ELSE
-             IF &S2 EQ 1 THEN 'Badge Admin' ELSE
-               IF &S2 EQ 2 THEN 'Badge Sales' ELSE
-                 IF &S2 EQ 3 THEN 'Srvc CC' ELSE 'Company Name';
-*
-SET &S3 = EDIT (&ORDSORT,'$$9$');
-SET &SORT3=IF &S3 EQ 0 THEN ' ' ELSE
-             IF &S3 EQ 1 THEN 'Badge Admin' ELSE
-               IF &S3 EQ 2 THEN 'Badge Sales' ELSE
-                 IF &S3 EQ 3 THEN 'Srvc CC' ELSE 'Company Name';
-*
-SET &S4 = EDIT (&ORDSORT,'$$$9');
-SET &SORT4=IF &S4 EQ 0 THEN ' ' ELSE
-             IF &S4 EQ 1 THEN 'Badge Admin' ELSE
-               IF &S4 EQ 2 THEN 'Badge Sales' ELSE
-                 IF &S4 EQ 3 THEN 'Srvc CC' ELSE 'Company Name';
-*
-************************************************************
-*Set delle variabili per il sort
-************************************************************
-*
-SET &PRI1 = DECODE &S1 ( 0 ' '
-                         1 'BY KI_ADMIN_BAD NOPRINT'
-                         2 'BY KI_SALES_BAD NOPRINT'
-                         3 'BY KO_SDU_CD    NOPRINT'
-                         4 'BY W_CO_NAM     NOPRINT' ELSE ' ');
-*
-SET &SEC2 = DECODE &S2 ( 0 ' '
-                         1 'BY KI_ADMIN_BAD NOPRINT'
-                         2 'BY KI_SALES_BAD NOPRINT'
-                         3 'BY KO_SDU_CD    NOPRINT'
-                         4 'BY W_CO_NAM     NOPRINT' ELSE ' ');
-*
-SET &TER3 = DECODE &S3 ( 0 ' '
-                         1 'BY KI_ADMIN_BAD NOPRINT'
-                         2 'BY KI_SALES_BAD NOPRINT'
-                         3 'BY KO_SDU_CD    NOPRINT'
-                         4 'BY W_CO_NAM     NOPRINT' ELSE ' ');
-*
-SET &QUA4 = DECODE &S4 ( 0 ' '
-                         1 'BY KI_ADMIN_BAD NOPRINT'
-                         2 'BY KI_SALES_BAD NOPRINT'
-                         3 'BY KO_SDU_CD    NOPRINT'
-                         4 'BY W_CO_NAM     NOPRINT' ELSE ' ');
-*
-TYPE Parametri di sort :
-TYPE &EMPTY
-TYPE &SORT1
-TYPE &SORT2
-TYPE &SORT3
-TYPE &SORT4
-TYPE
-RUN
-*
-***************************************************************
-** Set Up Value For Test
-***************************************************************
-**
-SET &CC_SER = ''''||''||&SERCC||''||'''';
-SET &TEST = EDIT (&SERCC,'999$$$');
-SET &SELCC = IF &TEST EQ 'ALL' OR '   ' THEN ' ' ELSE
-             'IF KO_SDU_CD CONTAINS ' | &CC_SER;
-*
-*******************************************************************************
-* Company Legal Name . Gli tolgo eventuali apici (SANITA' diventa SANITAb)
-*******************************************************************************
-*
-SET &CUSTOMER  = CTRAN (30,&COMPANY,39,32,'A30');
-SET &CO_LN     = ''''||&CUSTOMER||'''';
-*
-SET &TEST_CO   = IF &COMPANY NE 'ALL                           '
-                             OR '                              '
-                           THEN 'IF CO_LEG_NAM IS ' | &CO_LN ELSE ' ';
-*
-*******************************************************************************
-*
-***************************************************************
-*         Extract Data To Create Report.
-***************************************************************
-**
JOIN LO_SYS_ID IN EN_CO_LO TO ALL GP_LO_SYS_ID IN EN_GP AS JI7
-RUN
-**
DEFINE FILE EN_CO_LO
-*
-*******************************************************************************
-* CO_LEGAL_NAM e' il Legal Name senza apici. Es: UNIVERSITA' = UNIVERSITAblank
-*******************************************************************************
-*
W_CO_NAM/A30   = EDIT  (CO_LEGAL_NA,'999999999999999999999999999999$$');
CO_LEG_NAM/A30 = CTRAN (30,W_CO_NAM,39,32,CO_LEG_NAM);
-*
-*******************************************************************************
-*
W_LO_NAME/A15=     LO_NAME;
W_LO_DEPT/A30=     LO_DEPT;
W_LO_STREET/A40=   LO_STREET;
W_LO_POST/A9=      LO_POST_CODE;
W_LO_CITY/A30=     LO_CITY;
GP_SYSTEM/A21 = GP_SYS_TYPE_ | GP_SYS_SERIA;
GP_DEL_FLAG/I1=IF GP_DELETE_FL IS 'D' THEN 0 ELSE
               IF GP_DELETE_FL IS 'H' THEN 0 ELSE 1;
CO_DEL_FLAG/I1=IF CO_LO_DELETE IS 'D' THEN 0 ELSE
               IF CO_LO_DELETE IS 'H' THEN 0 ELSE 1;

END
-*
-RUN
-*
TABLE FILE EN_CO_LO
PRINT GP_LO_SYS_ID
AND GP_SYSTEM
AND W_CO_NAM
AND W_LO_NAME
AND W_LO_DEPT
AND W_LO_STREET
AND W_LO_POST
AND W_LO_CITY
-*
BY GP_SYS_ID
-*
&TEST_CO
-*
IF GP_DEL_FLAG IS 1
IF CO_DEL_FLAG IS 1
-*
ON TABLE HOLD AS ITA_071
END
-RUN
-**
-IF &LINES EQ 0 THEN GOTO NORECORD;
-TYPE %SPORT-I-ITA_07, ITA_071 Creato con &LINES record
-*
JOIN CLEAR JI7
JOIN GP_SYS_ID IN ITA_071 TO ALL KO_GP_SYS_ID IN EN_KO AS JI7
-RUN
-*
DEFINE FILE ITA_071
KO_DEL_FLAG/I1=IF KO_DELETE_FL IS 'D' THEN 0 ELSE
               IF KO_DELETE_FL IS 'H' THEN 0 ELSE 1;
-*
KO_ST_WAR/A6=EDIT (KO_WARR_STAR,'999999$$');
KO_ST_DAY/A2=EDIT (KO_WARR_STAR,'$$$$$$99');
KO_STAR_WAR/I6=EDIT (KO_ST_WAR);
KO_LENGT/I2 = EDIT (KO_MNTHS_WAR);
EXPIR_YYMM/I6 = AYM (KO_STAR_WAR,KO_LENGT,EXPIR_YYMM);
EXP_YM/A6 = EDIT (EXPIR_YYMM);
EXPIR_DATE/A8 = EXP_YM||KO_ST_DAY;
-*
KO_SDU_CD/A4 = EDIT (KO_SDU_CD,'9999$$');
END
-*
-RUN
-*
TABLE FILE ITA_071
PRINT GP_SYSTEM
AND W_CO_NAM
AND W_LO_NAME
AND W_LO_DEPT
AND W_LO_STREET
AND W_LO_POST
AND W_LO_CITY
AND KO_TYPE_CD
AND KO_QTY
AND KO_PSG_CD
AND KO_SDU_CD
AND EXPIR_DATE
AND KO_POS_IN_GP
AND KO_SW_HW_F
AND KO_SERIAL_NO
-*
BY KO_SYS_ID
-*
IF KO_NU_KO_SYS IS ' '
IF KO_DEL_FLAG  IS 1
ON TABLE HOLD AS ITA_072
END
-RUN
-**
-IF &LINES EQ 0 THEN GOTO NORECORD;
-TYPE %SPORT-I-ITA_07, ITA_072 Creato con &LINES record
-*
-VMS IF F$SEARC("QTMPDIR_PATH:FOCSORT.FTM") .NES. "" THEN DELETE/NOLOG/NOCONF QTMPDIR_PATH:FOCSORT.FTM;
-*
-VMS DELETE/NOLOG/NOCONF QTMPDIR_PATH:ITA_071.FTM;1
-TYPE %SPORT-I-ITA_07, ITA_071 Cancellato
-*
SET ALL = PASS
-RUN
-*
JOIN CLEAR *
JOIN KO_SYS_ID IN ITA_072 TO OS_KO_SYS_ID IN EN_OS AS JI7
-RUN
-*
-*
DEFINE FILE ITA_072
OS_DEL_FLAG/I1=IF OS_DELETE_FL IS 'D' THEN 0 ELSE
               IF OS_DELETE_FL IS 'H' THEN 0 ELSE 1;
END
-*
TABLE FILE ITA_072
PRINT GP_SYSTEM
AND W_CO_NAM
AND W_LO_NAME
AND W_LO_DEPT
AND W_LO_STREET
AND W_LO_POST
AND W_LO_CITY
AND KO_TYPE_CD
AND KO_QTY
AND KO_PSG_CD
AND KO_SDU_CD
AND KO_POS_IN_GP
AND KO_SERIAL_NO
AND EXPIR_DATE
AND KO_SW_HW_F
-*
BY  OS_LINK_ID
-*
IF  OS_DEL_FLAG  IS 1
ON TABLE HOLD AS ITA_073
END
-RUN
-**
-IF &LINES EQ 0 THEN GOTO NORECORD;
-TYPE %SPORT-I-ITA_07, ITA_073 Creato con &LINES record
-*
JOIN OS_LINK_ID IN ITA_073 TO ALL SL_OS_LINK_I IN EN_SL
-RUN
TABLE FILE ITA_073
PRINT GP_SYSTEM
AND W_CO_NAM
AND W_LO_NAME
AND W_LO_DEPT
AND W_LO_STREET
AND W_LO_POST
AND W_LO_CITY
AND KO_TYPE_CD
AND KO_QTY
AND KO_PSG_CD
AND KO_SDU_CD
AND KO_POS_IN_GP
AND KO_SERIAL_NO
AND EXPIR_DATE
AND KO_SW_HW_F
-*
BY  SL_SP_SYS_ID
ON TABLE HOLD AS ITA_074
END
-RUN
-**
-IF &LINES EQ 0 THEN GOTO NORECORD;
-TYPE %SPORT-I-ITA_07, ITA_074 Creato con &LINES record
-*
-VMS IF F$SEARC("QTMPDIR_PATH:FOCSORT.FTM") .NES. "" THEN DELETE/NOLOG/NOCONF QTMPDIR_PATH:FOCSORT.FTM;
-*
-VMS DELETE/NOLOG/NOCONF QTMPDIR_PATH:ITA_073.FTM;1
-TYPE %SPORT-I-ITA_07, ITA_073 Cancellato
-*
JOIN SL_SP_SYS_ID IN ITA_074 TO ALL SP_SYS_ID IN EN_SP14
-RUN
-*
DEFINE FILE ITA_074
-*
SP_DEL_FLAG/I1=IF SP_DELETE_FL IS 'D' THEN 0 ELSE
               IF SP_DELETE_FL IS 'H' THEN 0 ELSE 1;
-*
END
-RUN
-*
TABLE FILE ITA_074
PRINT W_CO_NAM
AND W_LO_NAME
AND W_LO_DEPT
AND W_LO_STREET
AND W_LO_POST
AND W_LO_CITY
AND KO_QTY
AND KO_TYPE_CD
AND KO_PSG_CD
AND KO_SDU_CD
AND KO_POS_IN_GP
AND KO_SERIAL_NO
AND GP_SYSTEM
AND EXPIR_DATE
AND KO_SW_HW_F
-*
BY SP_KI_SYS_ID
-*
IF  SP_DEL_FLAG  IS 1
-*
ON TABLE HOLD AS ITA_074B
END
-RUN
-**
-IF &LINES EQ 0 THEN GOTO NORECORD;
-TYPE %SPORT-I-ITA_07, ITA_074B Creato con &LINES record
-*
-VMS IF F$SEARC("QTMPDIR_PATH:FOCSORT.FTM") .NES. "" THEN DELETE/NOLOG/NOCONF QTMPDIR_PATH:FOCSORT.FTM;
-*
-VMS DELETE/NOLOG/NOCONF QTMPDIR_PATH:ITA_074.FTM;1
-TYPE %SPORT-I-ITA_07, ITA_074 Cancellato
-*
JOIN SP_KI_SYS_ID IN ITA_074B TO KI_SYS_ID IN CO_LO_KI AS FF
-RUN
-*
DEFINE FILE ITA_074B
-*
KI_DEL_FLAG/I1=IF KI_DELETE_FL IS 'D' THEN 0 ELSE
               IF KI_DELETE_FL IS 'H' THEN 0 ELSE 1;
-*
CONTRACT/A14=KI_K_NO|KI_VERSION_N|KI_QUOTE_NO;
CO_NAM/A30=EDIT (CO_LEGAL_NA,'999999999999999999999999999999$$');
-*
OGGI/I6=&OUJ;
YY/A2=EDIT (EXPIR_DATE,'$$99$$$$');
MM/A2=EDIT (EXPIR_DATE,'$$$$99$$');
DD/A2=EDIT (EXPIR_DATE,'$$$$$$99');
EXPIR_DT/A6=YY||MM||DD;
EXP_DAT/I6=EDIT (EXPIR_DT);
RES/I8 = YMD (EXP_DAT,OGGI);
STATUS_1/A1=IF RES LT 0 THEN 'W' ELSE IF RES GT 365 THEN 'I' ELSE 'F';
OPT_STATUS/A1=IF KI_STATUS EQ 'S' THEN 'K'  ELSE
              IF KI_STATUS EQ 'Q' THEN 'Q'  ELSE STATUS_1;
-*
END
-RUN
-*
TABLE FILE ITA_074B
PRINT W_CO_NAM
AND W_LO_NAME
AND W_LO_DEPT
AND W_LO_STREET
AND W_LO_POST
AND W_LO_CITY
AND KO_TYPE_CD
AND KO_QTY
AND KO_PSG_CD
AND KO_SDU_CD
AND KO_POS_IN_GP
AND EXPIR_DATE
AND KI_K_NO
AND KO_SERIAL_NO
-*
AND CO_NAM
-*
AND KI_K_ADMIN_C
AND KI_STATUS
AND KI_ADMIN_BAD
AND KI_SALES_BAD
AND KI_START_DT
AND CONTRACT
AND OPT_STATUS
AND KO_SW_HW_F
-*
BY GP_SYSTEM
-*
ON TABLE HOLD AS ITA_075
END
-RUN
-**
-IF &LINES EQ 0 THEN GOTO NORECORD;
-TYPE %SPORT-I-ITA_07, ITA_075 Creato con &LINES record
-*
-VMS IF F$SEARC("QTMPDIR_PATH:FOCSORT.FTM") .NES. "" THEN DELETE/NOLOG/NOCONF QTMPDIR_PATH:FOCSORT.FTM;
-*
-VMS DELETE/NOLOG/NOCONF QTMPDIR_PATH:ITA_074B.FTM;1
-TYPE %SPORT-I-ITA_07, ITA_074B Cancellato
-*
-***************************************************************************-
-***************************************************************************-
-***************************************************************************-
-*
-TYPE
-TYPE ************************************************************************
-TYPE modulo esterno per la determinazione delle differenze di configurazione.
-TYPE ************************************************************************
-*
-INCLUDE SPORT$$P_ROOT:[LOCAL.EXE]ITA_07_D.FEX
-RUN
-*
-***************************************************************************-
-* Questo viene dal modulo _D.FEX. serve per sapere se il modulo ha dato
-* NORECORD.
-***************************************************************************-
-*
-IF &NO_REC_D EQ 'Y' THEN GOTO NORECORD;
-*
-***************************************************************************-
-***************************************************************************-
-***************************************************************************-
-*
-VMS IF F$SEARC("QTMPDIR_PATH:FOCSORT.FTM") .NES. "" THEN DELETE/NOLOG/NOCONF QTMPDIR_PATH:FOCSORT.FTM;
-*
-***************************************************************************-
-* costruisco un file con le opzioni piu' rappresentative di ogni systema
-***************************************************************************-
-*
-*  -AVANTI QUESTO VENIVA DAL 072
-*
-*
DEFINE FILE ITA_075
SYS_STATUS/A1 = OPT_STATUS;
END
-*
TABLE FILE ITA_075
PRINT SYS_STATUS
BY    GP_SYSTEM
BY LOWEST 1 KO_POS_IN_GP
IF KO_SW_HW_F IS H
-*
ON TABLE HOLD AS ITA_076
END
-RUN
-**
-IF &LINES EQ 0 THEN GOTO NORECORD;
-TYPE %SPORT-I-ITA_07, ITA_076 Creato con &LINES record
-*
JOIN GP_SYSTEM IN ITA_07T TO GP_SYSTEM IN ITA_076
-RUN
-*
DEFINE FILE ITA_07T
TYPE_CD_KO/A11=EDIT (KO_TYPE_CD, '99-99999-99');
EX_YY/A2=EDIT (EXPIR_DATE,'$$99$$$$');
EX_MM/A2=EDIT (EXPIR_DATE,'$$$$99$$');
EX_DD/A2=EDIT (EXPIR_DATE,'$$$$$$99');
EX_MESE/A3=DECODE EX_MM (01 'JAN'
                         02 'FEB'
                         03 'MAR'
                         04 'APR'
                         05 'MAY'
                         06 'JUN'
                         07 'JUL'
                         08 'AUG'
                         09 'SEP'
                         10 'OCT'
                         11 'NOV'
                         12 'DEC');
-*
EXP_DT_FINAL/A9=EX_DD||'-'||EX_MESE||'-'||EX_YY;
EXP_DT_FINAL/A9=IF EXP_DT_FINAL IS '17-NOV-58' THEN '         '
                ELSE EXP_DT_FINAL;
GP_SYSTEM_2/A22 = EDIT (GP_SYSTEM,'999999-999999999999999');
TESTINO/A1 = IF KI_ADMIN_BAD IS-NOT '      ' THEN 'Y' ELSE
             IF KI_SALES_BAD IS-NOT '      ' THEN 'Y' ELSE 'N';
-*
FULL_SITE/A154 = W_LO_NAME|W_LO_DEPT|W_LO_STREET|W_LO_POST|W_LO_CITY;
-*
END
-*
-*******************************************************************************
-*
-* Questa mi serve per sapere se per questa selezione ci sono record.
-* Cosi' evito una pagina con sdolo i puntini.
-*
-*******************************************************************************
-*
TABLE FILE ITA_07T
PRINT
W_CO_NAM
W_LO_NAME
W_LO_DEPT
TYPE_CD_KO
IF TESTINO IS Y
IF W_LO_NAME IS-NOT '.'
ON TABLE HOLD AS ITA_7P1
END
-RUN
-**
-IF &LINES EQ 0 THEN GOTO NOREPORT1;
-*
-TYPE %SPORT-I-ITA_07, ITA_7P1 Creato con &LINES record
-*
-VMS DELETE/NOLOG/NOCONF QTMPDIR_PATH:ITA_7P1.FTM;1
-TYPE %SPORT-I-ITA_07, ITA_7P1 Cancellato
-*
SET PANEL = 132
-RUN
-*******************************************************************************
-* report 1
-*******************************************************************************
-*
TABLE FILE ITA_07T
HEADING
"ITA_07"
"Company Confidential <44 STATO DELLE OPZIONI E BASE INSTALLATA
 <121 Pag. <TABPAGENO"
"SPORT V2.2/REPORT LOCALI     <112 Creato il &TODAY"
"-------------------------------------------------------------------------------
---------------------------------------------------"
"<6 .-------- System -----------.-------------- Option ----------------.--------
-------- Contract --------------------------."
"<6  Type   Serial No         S Type        Qty Psg    St   Warr. End   CC    No
    Version  Co Legal Name"
"<6 .------.-----------------.-.---------------.------.----.-----------.-----.--
------------.-------------------------------."
PRINT
TYPE_CD_KO        AS ''    IN 34
KO_QTY            AS ''    IN 46
KO_PSG_CD         AS  ''   IN 50
AND OPT_STATUS    AS ''    IN 58
AND EXP_DT_FINAL  AS ''    IN 63
-*
AND KI_K_ADMIN_C  AS ''    IN 75
AND CONTRACT      AS ''    IN 80
AND SEGNO         AS ''    IN +0
AND CO_NAM        AS ''    IN 95
-*
&PRI1
&SEC2
&TER3
&QUA4
-*
BY FULL_SITE       NOPRINT SUBHEAD
" "
"  Co Legal Name : <W_CO_NAM"
"  Location :      <W_LO_NAME>      <57> Address : Dept. <74 <W_LO_DEPT>"
" <74 <W_LO_STREET> "
" <74 <W_LO_POST> <W_LO_CITY>"
" "
-*
BY GP_SYSTEM_2    AS ''    IN 7     SKIP-LINE
BY SYS_STATUS     AS ''    IN 32
BY KO_POS_IN_GP   NOPRINT
-*
IF TESTINO IS Y
IF W_LO_NAME IS-NOT '.'
-*
ON KI_ADMIN_BAD SUBHEAD
"  *** Admin Rep : <KI_ADMIN_BAD  "
-*
ON KI_SALES_BAD SUBHEAD
"  *** Admin Sales : <KI_SALES_BAD"
-*
ON W_CO_NAM PAGE-BREACK
-*
FOOTING
"  <40  D I G I T A L      C O N F I D E N T I A L   "
-*
ON TABLE SUBHEAD
"-------------------------------------------------------------------------------
---------------------------------------------------"
"Report sortato per : &SORT1 , &SORT2 ,
<+1 &SORT3 , &SORT4"
"-------------------------------------------------------------------------------
---------------------------------------------------"
END
-RUN
-**
-*******************************************************************************
-*
-NOREPORT1
-*
-*******************************************************************************
-*
TABLE FILE ITA_07T
PRINT
W_CO_NAM
W_LO_NAME
W_LO_DEPT
TYPE_CD_KO
IF KI_ADMIN_BAD IS '      '
IF KI_SALES_BAD IS '      '
IF W_LO_NAME IS-NOT '.'
-*
ON TABLE HOLD AS ITA_7P2
END
-RUN
-**
-IF &LINES EQ 0 THEN GOTO NOREPORT2;
-*
-TYPE %SPORT-I-ITA_07, ITA_7P2 Creato con &LINES record
-*
-VMS DELETE/NOLOG/NOCONF QTMPDIR_PATH:ITA_7P2.FTM;1
-TYPE %SPORT-I-ITA_07, ITA_7P2 Cancellato
-*
-*******************************************************************************
-* report 2
-*******************************************************************************
-*
TABLE FILE ITA_07T
HEADING
"ITA_07"
"Company Confidential <44 STATO DELLE OPZIONI E BASE INSTALLATA
<121 Pag. <TABPAGENO"
"SPORT V2.2/REPORT LOCALI     <112 Creato il &TODAY"
"-------------------------------------------------------------------------------
---------------------------------------------------"
"<6 .-------- System -----------.-------------- Option ----------------.--------
-------- Contract --------------------------."
"<6  Type   Serial No         S Type        Qty Psg    St   Warr. End   CC    No
    Version  Co Legal Name"
"<6 .------.-----------------.-.---------------.------.----.-----------.-----.--
------------.-------------------------------."
PRINT
KO_QTY            AS ''    IN 46
KO_PSG_CD         AS  ''   IN 50
AND OPT_STATUS    AS ''    IN 58
AND EXP_DT_FINAL  AS ''    IN 63
-*
AND KI_K_ADMIN_C  AS ''    IN 75
AND CONTRACT      AS ''    IN 80
AND SEGNO         AS ''    IN +0
AND CO_NAM        AS ''    IN 95
-*
&PRI1
&SEC2
&TER3
&QUA4
-*
BY FULL_SITE       NOPRINT SUBHEAD
" "
"  Co Legal Name : <W_CO_NAM"
"  Location :      <W_LO_NAME>      <57> Address : Dept. <74 <W_LO_DEPT>"
" <74 <W_LO_STREET> "
" <74 <W_LO_POST> <W_LO_CITY>"
" "
-*
BY GP_SYSTEM_2    AS ''    IN 7
BY SYS_STATUS     AS ''    IN 32
BY KO_POS_IN_GP   NOPRINT
BY TYPE_CD_KO     AS ''    IN 34
-*
IF KI_ADMIN_BAD IS '      '
IF KI_SALES_BAD IS '      '
IF W_LO_NAME IS-NOT '.'
-*
-*
ON KI_ADMIN_BAD SUBHEAD
"  *** Admin Rep : <KI_ADMIN_BAD  "
-*
ON KI_SALES_BAD SUBHEAD
"  *** Admin Sales : <KI_SALES_BAD"
-*
ON W_CO_NAM  PAGE-BREAK
-*
FOOTING
"  <40  D I G I T A L      C O N F I D E N T I A L   "
-*
ON TABLE SUBFOOT
"-------------------------------------------------------------------------------
---------------------------------------------------"
"Report sortato per : &SORT1 , &SORT2 ,
<+1 &SORT3 , &SORT4"
END
-RUN
-**
-*******************************************************************************
-*
-NOREPORT2
-*
-*******************************************************************************
-*
-TYPE %SPORT-I-FOCTER, Procedura ITA_07 Terminata
-QUIT FOCUS 1
-*
-NORECORD
-SET &&NODAT='YES';
-TYPE %SPORT-I-IT7NTGTD, nessun record selezionato
-QUIT FOCUS 0
-**
-SPORT5
-TYPE %SPORT-I-IT7PFNTFD, Non trovato il file parametri
-QUIT FOCUS 2
-**
-*******************************************************************************
-**                      E N D     O F     S O U R C E   
-*******************************************************************************
    

    Fabio,
    
    I am confused; there is no -CRTFORM in the procedure you posted.
    
    Am I missing something ? Can you post the program which is generating
    the error(s) ?
    
    Regards,
    
    Paul

        Hi Paul, 

	Thanks for your soon reply.
	I'm sorry I had a typing error while creating the entry.
	Here is the program with the problem.
	Thanks again
	Fabio.


	
-***************************************************************************-
-***************************************************************************-
-*
-*    System        :     Sport
-*
-*    Procedure     :     Ita_07_s.fex
-*
-*    Author        :     Fabio Ferrari
-*
-*    Data          :     Feb-93
-*
-*    Description   :     Option Status and Installed Base List
-*
-*    Output        :     Run Sport$$d_lsrc:ita_07_r.com
-*
-*    Notes         :     Sport$$f_spacedb Is The Database Of Space
-*
-***************************************************************************-
-***************************************************************************-
-SET &QUIT=OFF;
-**
-*******************************************
-* Get Data Format DD-MMM-YY And DD-MMM-YYYY
-*******************************************
-**
-SET &ALLTODAY=GETSTIME('A8');
-SET &ALLTODAY2=CVTSTIME(0,&ALLTODAY,'A20');
-RUN
-*
-SET  &TODAY=EDIT(&ALLTODAY2,'9999999$$99$$$$$$$$$');
-SET  &NOW=EDIT(&ALLTODAY2,'$$$$$$$$$$$$99999$$$');
-RUN
-*
-RUN
-**
-*******************************************
-* Prepare The Variables For Mask
-*******************************************
-UP
-SET &CONF     = 'Y';
-SET &STTIME   = &NOW;
-SET &STDATE   = &TODAY;
-SET &SUB_ERR   = '       ';
-SET &ORD_ERR   = '       ';
-SET &STT_ERR   = '       ';
-SET &CO_NAME = 'ALL                           ';
-SET &SYSTEM_CC = 'ALL   ';
-SET &ORDSORT = '1234';
-RUN
-**
-OVER
-SET &PFKEY='     ';
-CRTFORM                                                                        
-* TEMPORARY FIELD DEFINITION &STT_ERR    A7
-* TEMPORARY FIELD DEFINITION &SUB_ERR    A7
-* TEMPORARY FIELD DEFINITION &STDATE     A9
-* TEMPORARY FIELD DEFINITION &TODAY      A9
-* TEMPORARY FIELD DEFINITION &NOW        A5
-* TEMPORARY FIELD DEFINITION &STTIME     A5
-* TEMPORARY FIELD DEFINITION &CONF       A1
-* TEMPORARY FIELD DEFINITION &CO_NAME    A30
-* TEMPORARY FIELD DEFINITION &SYSTEM_CC  A6
-* TEMPORARY FIELD DEFINITION &ORDSORT    A4
-* TEMPORARY FIELD DEFINITION &ORD_ERR    A7
-"<.G. "
-"  �������������������������������������������������������������������������"
-"  � <.HG.<5>ITA_07 - Stato delle Opzioni e Base Installata   <D.&TODAY<.HG. ,
-<66><D.&NOW<.G.   �"
-"  �������������������������������������������������������������������������"
-"  � Selezioni:<75>�"
-"  �<26><.HG. <41><.G.<41>Il report puo` essere sortato per:�"
-"  �  Company name<24>:<.HUT.&CO_NAME><.G. <75>�"
-"  �  Group Cost Centre :<.HUT.&SYSTEM_CC><.G. <45><.HG.<45>1)<.G. Badge Admin
-<75>�"
-"  �<26><.HG. <32><.G. <45><.HG.<45>2)<.G. Badge Sales<75>�"
-"  �<45><.HG.<45>3)<.G. Srvc Delivery CC & <67>Unit    �"
-"  �<45><.HG.<45>4)<.G. Company Name<75>�"
-"  �<45><.HG.  <.G. <75>�"
-"  � Seleziona quale Sort vuoi applicare:   <.HUT.&ORDSORT><.HGD.&ORD_ERR<.G. 
-<75>�"
-"  �������������������������������������������������������������������������"
-"  �<24>Parametri Per il Batch Job<75>�"
-"  �������������������������������������������������������������������������"
-"  �  Data<24>:<.HUT.&STDATE><.HGD.&SUB_ERR<.G.    <.HG. <55><.G.   <.HG. 
-<65><.G. <75>�"
-"  �  Ora<24>:<.HUT.&STTIME><.G.    <.HGD.&STT_ERR<.G.    <.HG.  <.G. 
-<58><.HG. <65><.G. <75>�"
-"  �  Confermi?  (Y/N)  :<.HUT.&CONF><.G. <75>�"
-"  �������������������������������������������������������������������������"
-RUN
-**
-IF &PFKEY NE ENTR THEN GOTO UP;
-**
-*******************************************
-* If Not Confirmed Goto Exit
-*******************************************
-SET &ON = DECODE &CONF (Y GO  ELSE STOP );
-IF &ON EQ STOP  THEN GOTO ENDED;
-**
-********************************************************************
-* Display The Screen Saying Wait.....
-********************************************************************
-VMS TYPE SPORT$$D_DAT:DISPLAY_WAIT.LIS
-**
-SET &GOTO = 'ON3';
-**
-*******************
-* Check Start Time
-*******************
-SET &TI=EDIT (&STTIME, '99$$$');
-SET &ME=EDIT (&STTIME, '$$$99');
-**
-**
-SET &STT_ERR   =  '       ';
-IF &TI LT 24 THEN GOTO TIOK;
-SET &STT_ERR = 'FOR_ERR';
-SET &GOTO = 'OVER';
-TIOK
-**
-IF &TI.TYPE EQ N THEN GOTO TIOK2;
-SET &STT_ERR = 'FOR_ERR';
-SET &GOTO = 'OVER';
-TIOK2
-**
-IF &ME LT 60 THEN GOTO MEOK;
-SET &STT_ERR = 'FOR_ERR';
-SET &GOTO = 'OVER';
-MEOK
-**
-IF &ME.TYPE EQ N THEN GOTO MEOK2;
-SET &STT_ERR = 'FOR_ERR';
-SET &GOTO = 'OVER';
-MEOK2
-**
-*******************************************
-* Check Dates
-*******************************************
-**
-SET &SUB_ERR = '       ';
-SET &&CHDATE = &STDATE;
EXEC SPORT$$D_EXE:CON_DAT.FEX
-RUN
-IF &&RETVAL EQ '0' OR '2' THEN GOTO ON5;
-RUN
-SET &SUB_ERR = 'FOR_ERR';
-SET &GOTO = 'OVER';
-**
-ON5
-GOTO &GOTO
-**
-ON3
-**                                    
-*******************************************************************************
-*  Controllo sul sort order inputato dall'utente
-*******************************************************************************
-*
-SET &GOTO = 'ON6';
-**
-INCLUDE SPORT$$D_LEXE:SORT_4.FEX
-GOTO &GOTO
-*
-ON6
-* 
-*******************************************************************************
-*  definizione del file e scrittura dei parametri 
-*******************************************************************************
-* 
FI PARA  DISK SPORT$$D_LWRK:ITA_07.PAR
-RUN
-**
-WRITE PARA &CO_NAME&SYSTEM_CC&ORDSORT&VUOTO
-RUN
-**
-SET &Y = EDIT (&STDATE,'$$$$$$$99');
-SET &M = EDIT (&STDATE,'$$$999$$$');
-SET &D = EDIT (&STDATE,'99$$$$$$$');
-**
-SET &START = &D||'-'||&M||'-'||'19'||&Y||':'||&TI||':'||&ME||':00';
-**
-*****************
-* Start Batch Job
-*****************
-**
-VMS @SPORT$$D_LRPC:ITA_07_B.COM &START
-**
-ENDED
FIN
-******************************************************************************
    

    Hi Fabio,
    
    I have run your procedure, with some minor additions and alterations to
    allow for missing .fex files and logical names, and I do not get any
    problem. Can you give any more information ? 
    Can you confirm that absolutely nothing has changed, either in terms of
    hardware or software on the system where this procedre runs, since it last
    ran successfully?
    
    Regards,
    
    Paul