Conference ilbbak::ibi_focus

343.0. "Page skip problem." by RUTILE::HOMOLA () Tue May 29 1990 11:01

    Since several days we try to print a relatively simple report and it
    always creates a blank page after a normal full page. 
    We tried different changes in the program, but it always prints
    this blank pages. As this report contains normally several hundreds
    of pages, we use twice more paper.
    
    Could a "guru" have a look at the source code attached below and
    let us know if it is a known FOCUS bug or a programming error?
    
    Thanks in advance,
    
    Jiri
    
    PS. We use FOCUS 5.2 release.
    
--------------------------------------------------------------------------    

FILEDEF PAX_MPRO DISK MOD_PROD

OFFLINE CLOSE

FILEDEF OFFLINE DISK UPD_RPT

DEFINE FILE PAX_MPRO
    DATA_CHNG/A26 = DECODE FIELD_ID (
         '  3'  'Part Effective Date'
         '  5'  'Part Short Description'
         '  8'  'Hardware/Software flag'
         '  9'  'High End Product flag'
         ' 12'  'E/U Discount code'
         ' 13'  'OEM Discount code'         
         ' 17'  'SPD Number'
         ' 18'  'Training Credit Qty'
         ' 19'  'Soft.Prod. operating cd.'
         ' 20'  'Primary Supply Point'
         ' 21'  'Secondary Supply Point'
         ' 22'  'Part alternative id.'
         ' 23'  'Product Pricing respons.'
         ' 24'  'Product Service respons.'
         ' 25'  'Sales activity code'
         ' 26'  'Product technology level'
         ' 27'  'Corporate Status'
         ' 28'  'Area Status 1'
         ' 29'  'Area Status date 1'
         ' 30'  'Area Status 2'
         ' 31'  'Area Status date 2'
         ' 32'  'Booking code'
         ' 33'  'Volume Price Matrix'
         ' 34'  'Quantity Measurement code'
         '201'  'Price Book'
         '202'  'Subsidiary Status'
         ELSE 'Other') ;

-*    DAT1/I6DMTY = &DMY;
END
-SET &DD = EDIT(&DMY,'99$$$$');
-SET &MM = EDIT(&DMY,'$$99$$');
-SET &YY = EDIT(&DMY,'$$$$99');
-SET &MMM = DECODE &MM (01 JAN 02 FEB 03 MAR 04 APR 05 MAY 06 JUN 07 JUL 
-                       08 AUG 09 SEP 10 OCT 11 NOV 12 DEC);
-SET &DAT1 = &DD || '-' || &MMM || '-' || &YY;


TABLE FILE PAX_MPRO

    HEADING
    "<1>Digital Confidential <100>PAGE<TABPAGENO"
    " "
    " <1>Date : &DAT1 <30>PART ID MODIFICATIONS "
    " "
    " <30>(AREA PRODUCT DATA)"
    " "
    " <30>Start Date : &START_DATE"
    " "
    " "
    PRINT
        PART_ID      AS 'Part Id         '              IN  29  AND
        OLD_VALUE    AS 'Old Value                    ' IN  47  AND
        NEW_VALUE    AS 'New Value                    ' IN  78  AND
        EFFECTY_DATE AS 'Date   '                       IN 109  AND
        USERNAME     AS 'Username  '                    IN 120

    BY FIELD_ID      NOPRINT 
    BY DATA_CHNG     AS 'Data Element              '    IN   1 

    ON FIELD_ID SKIP-LINE 

END 

FIN

    
    
    If the total width of a line in the report is more than 132 characters
    FOCUS will split a page into two pages, one with the first 132
    characters and one with the rest. 
    
    It wouldn't surprise me if your report contains lines (or perhaps
    the heading?) of 133 characters of which the last character is always
    a space. So check the size of the last field (USERNAME)!
    
    Let's hope this is of any help,
                                       Andr�
                                            

    Thanks, you were right.
    
    Our lines were more than 132 char. large. 
    
    Jiri