Conference share::zap

  Hi Claudio,

  ZAP V3.8 is the current, supported version, and does run on VMS V5.0*
  systems reliably.  We use ZAP V3.8 on all of our ALL-IN-1 systems
  because it *is* reliable, and *does* handle both the main and sub
  processes of an ALL-IN-1 user.

  Perhaps your customer's problem is in their ZAP.DAT layout or they
  may not be starting and stopping ZAP on a daily basis.  Please post
  your customer's ZAP.DAT for examination.

  HTH,

	Ron

  Hi Keith,

  I have a user who's reported a problem with ZAP while using VMSmail:

  "As for ZAP, I was in VMSmail typing a lengthy mail message when I got 
  the "warning".  This happened to me (in VAXmail) last summer too.  
  It's as if ZAP sees no terminal input while you're in VAXmail."

  I'm unable to reproduce this situation; do you have any ideas?  BTW,
  VAX/VMS V4.7 ...

  Thanks in advance!

	Ron

    It has been documented that ZAP may think that a user is idle while
    they are using VMSmail.  It works as follows:
    
    	1.  VMSmail uses the $CREATE system service to create a
    	    temporary file to be sent.  This utility is very effecient
            and does not use much CPU time at all.
    
    	    The system uses 1 buffered i/o for each RETURN key pressed.
    	    Since this counts a 2 units of work for ZAP, 3 RETURNs are
    	    needed per minute if your sensitivity is set to 5.
    
    	2.  The user sees the warning about being idle and types
     	    "faster".  But "faster" may only contain 2 lines per minute
    	    which keeps them idle.
    
    	3.  ZAP kills the process because it is idle.
    
    There are several ways to correct this.  The first is to give
    the VMSmail image a longer time limit.  Perhaps an hour or so. 
    The second, and I feel better option, is to have your users use
    the editor when creating mail messages.  This has the advantage
    of using more cpu time and allowing the user more flexibility.
    
    In the next reply is a command procedure used at this site which
    will put the user into the EDT editor while in mail.  Note that
    it uses a logical name AND a symbol.  If the user redefines the
    symbol for MAIL in their LOGIN.COM, it would need to be changed
    for each user.
    
    The command procedure also uses the DECspell utility to check the
    document before it is sent.
    
    					Keith Maconi

$ !	MAIL_EDIT.COM
$    
$ !	Inputs:
$ !
$ !		P1 = Input file name	[= filespec given on WRITE or REPLY
$ !					 command, otherwise null]
$ !		P2 = Output file name	[= tempfile if /LAST specified]
$
$ !	Usage:
$ !
$ !		NOTES_EDIT is used by defining the appropriate logicals for
$ !		MAIL and NOTES, as follows:
$ !
$ !		$ define MAIL$EDIT  device:[directory]MAIL_EDIT.COM
$ !		$ define NOTES$EDIT device:[directory]MAIL_EDIT.COM
$ !
$ !		It is then invoked by the MAIL the commands SEND/EDIT and
$ !		REPLY/EDIT and the NOTES commands WRITE/EDIT and REPLY/EDIT.
$ !
$ !		The /EDIT qualifier can be made the default for MAIL by entering
$ !		MAIL with the MAIL/EDIT command. If you want to do this always,
$ !		you should consider placing something like:
$ !
$ !		$ MAIL :== MAIL/EDIT
$ !
$ !		in your LOGIN.COM file.
$
$ !	Set up commands to produce functions wanted
$
$   	edit	:= edit/edt
$	spell	:= spell
$
$ !	Do not edit below this point
$
$	save_verify = f$verify(0)
$	on control_y then goto main_menu
$
$	if p1 .eqs. "" then p1 = p2
$	goto edit
$
$ !	Determine function desired
$ main_menu:
$	read /error=quit /end=exit sys$command function -
		/prompt="Enter function: Edit EXit Quit Spell (E/EX/Q/S) [Exit] "
$	if function .eqs. "" then function := exit
$
$	function := 'f$extract(0,2,function)
$	if ( function .eqs. "E" ) .or. ( function .eqs. "ED" ) then goto edit
$	if function .eqs. "EX" then goto exit
$	if ( function .eqs. "Q" ) .or. ( function .eqs. "QU" ) then goto quit
$	if ( function .eqs. "S" ) .or. ( function .eqs. "SP" ) then goto spell
$
$	write sys$output "%MAIL_EDIT-E-UNKWNFN, Unknown function,"
$	write sys$output " - Please enter EDIT, EXIT, QUIT, or SPELL."
$	goto main_menu
$
$ !	Create/Edit the file
$ edit:
$	define/nolog/user sys$input sys$command:
$	edit /output='p2 'p1
$	p1 = p2
$	goto main_menu
$
$ !	Check the spelling in the document
$ spell:
$	define/user sys$input sys$command:
$	spell 'p2'
$	goto main_menu
$
$ !	Do not create a file
$ quit:
$	delete/nolog 'p2;*
$	save_verify = f$verify('save_verify)
$	exit
$
$ !	Normal exit
$ exit:
$	purge/nolog 'p2
$	save_verify = f$verify('save_verify)
$	exit
$