Conference azur::mcc

    This particular problem is not actually a DECmcc fault. It wouldn't
    have mattered which version of DECmcc you have.
    
    The problem is that MCC Attributes in DNS are binary coded values
    that happen to have values that are less than the binary value of
    the space character (the lowest printable ascii character). DNS$CONTROL
    only deals with codes from SPACE on up. Soooo, when you created the
    replica set and (I assume) COPYed the directories with DNS$CONTROL,
    it didn't copy the DECmcc Attributes.
    
    There is a fix for this. The problem is in DNS$LIB.EXE 
    
    The next note will contain a patch for it.
    
    You will need to recreate the replica set after applying the patch
    but you don't need to re-register the DECmcc entities.
    
    s/rob

$! see below for details of patch
$! To install, simply run this .com file.
$! 
$    verify_save 	= "noverify"
$    if f$verify() .eq. 1 then -
	verify_save = "verify"
$    default_save 	= f$environment("default")
$!
$    if f$trnlnm("exe$dir") .eqs. "" then -
        define exe$dir sys$system, sys$library
$!----------------------------------------------------------------------------
$    file		= "dns$lib.exe"
$!----------------------------------------------------------------------------
$    x 			= f$search("exe$dir:''file'")
$    if x .nes. "" then -
	goto filefound
$    write sys$output "File ''file' not found"
$    exit
$!
$filefound:
$    defdir		= f$parse("''x'",,,"device") -
			+ f$parse("''x'",,,"directory")
$    on control_y then - 
	goto cleanup
$!
$    set verify 
$    set default 'defdir'	! force updated file to same directory
$!
$    patch 'file'
!
!  Patch to DNS$LIB.EXE in V1.1 to fix dns$names_simplematch such that NULL
!  simplenames collate lower than all other types.
!  (ref module NAMES_LIB in DNS 1.1 listings)
!  This is to fix a problem which manifested itself under MCC wherein
!  attributes with binary (as opposed to normal) names on objects, were not 
!  copied when the directory in which the objects resided was replicated
!  (ie. using DNS$CONTROL COPY DIRECTORY command). Any binary named attributes
!  would not be returned for requests serviced by the clearinghouse containing
!  the directory replica.
!
	set eco 1
	define simplematch=420D
	define x=simplematch-0C
	repl/i x+0E
!					make room for JMP to patch area
		'MOVAB   W^0FDF8(SP),SP'
		'MOVAL   W^0FDFA(FP),R3'
		exit
!					restore instructions replaced by JMP
		'MOVAB   W^0FDF8(SP),SP'
		'MOVAL   W^0FDFA(FP),R3'
!					now for the inserted code
		'MOVL	B^04(AP),R1'	! name1 addr
		'MOVL	B^08(AP),R2'	! name2 addr
		'CMPB	(R1),#0'
		'BNEQ	L2'		! name1 type not NULL
		'CMPB	(R2),#0'
		'BNEQ	L1'		! name2 type not NULL
		'MOVL	#0,R0'		! both NULL - return EQL
		'RET'
	'L1:	 MNEGL	#1,R0'		! name1 NULL, name2 ^NULL - return LSS
		'RET'
	'L2:	 CMPB	(R2),#0'
		'BNEQ	L4'		! name2 type not NULL
		'CMPB	(R1),#0'
		'BNEQ	L3'		! name1 type not NULL
		'MOVL	#0,R0'		! both NULL - return EQL
		'RET'
	'L3:	 MOVL	#1,R0'		! name1 ^NULL, name2 NULL - return GTR
		'RET'
	'L4:	 NOP'			! continue in original code
		exit
	UPDATE
	EXIT
$    if .not. $status then -
	goto cleanup
$    x=f$environment("DEFAULT")+file
$    if f$file_attributes(x,"KNOWN") then -
         install replace 'x
$cleanup:
$    set default 'default_save'
$    set 'verify_save'
$    exit

    
    Thanks Rob,
    
    the patch has solved the problem. We're now able to shutdown the
    DNS-Master and having all MCC information on the Read Only Replica
    available.
    
    Best regards Uwe