| Here is a copy of the .bat file Brian is using.
regards,
Martin.
@REM @(#)nsrsql.bat 1.6 96/12/12 Copyright (c) 1996, Legato Systems, Inc.
@REM
@REM All rights reserved.
@REM
@ECHO OFF
SETLOCAL
REM
REM ===============================================================
REM *** P L E A S E R E A D ***
REM Because nsrexecd does not pass the Path environment variable
REM down, you will have to enter the paths for for nsrdbcc.exe,
REM nsrsqlsv.exe and sqlmaint.exe commands.
REM ===============================================================
REM
SET SQLPATH=C:\mssql\binn\
SET NSRPATH=E:\nsr\bin\
REM
REM ===============================================================
REM SQL Server 6.0 doesn't have SQLMAINT.EXE, so you have to use
REM NSRDBCC.EXE to check database. If you are running SQL Server
REM 6.5, we recommand you to use SQLMAINT.EXE to check database.
REM ===============================================================
REM
REM Uncomment following statement if you are running SQL Server 6.0
SET DBCCCMD=%NSRPATH%nsrdbcc.exe
REM
REM Uncomment following statement if you are running SQL Server 6.5
REM SET DBCCCMD=%SQLPATH%sqlmaint.exe
REM
REM ===============================================================
REM DBCC options:
REM -CkDB | CkDBNoIdx
REM -CkAl | CkAlNoIdx
REM -CkTxtAl
REM -CkCat
REM
REM Different DBCC request will be invoked depends on the DBCC
REM options specified as follow:
REM
REM -CkDB: DBCC CHECKDB(dbName)
REM -CkDBNoIdx: DBCC CHECKDB(dbName, NOINDEX)
REM -CkAl: DBCC CHECKALLOC(dbName)
REM -CkAlNoIdx: DBCC CHECKALLOC(dbName, NOINDEX)
REM -CkTxtAl: DBCC TEXTALL(dbName)
REM -CkCat: DBCC CHECKCATALOG(dbName)
REM
REM If DBCCOPT is not set, then DBCC will not be invoked. Just
REM comment out following statement if you don't want to run DBCC.
REM ===============================================================
REM
SET DBCCOPT=-CkDB -CkAl -CkCat
REM
REM ===============================================================
REM DBCC report file:
REM nsr_YYYYMMDD.rpt
REM ===============================================================
REM
SET DBCCRPT=c:\mssql\log\nsr.rpt
REM
REM ===============================================================
REM Local nsrsqlsv options
REM ===============================================================
REM
SET NSRSQLOPT=
REM
REM ===============================================================
REM XBSA environment variables
REM ===============================================================
REM
REM SET NSR_DATA_VOLUME_POOL=BSMSData
REM SET NSR_LOG_VOLUME_POOL=BSMSLogs
REM SET NSR_SERVER=server
REM SET NSR_BACKUP_LEVEL=full
REM SET NSR_CLIENT=client
REM SET NSR_COMPRESSION=FALSE
REM SET NSR_DEBUG_FILE=C:\win32app\nsr\applogs\xbsa.messages
REM SET NSR_DEBUG_LEVEL=1
REM SET NSR_GROUP=savegroup
REM SET NSR_NO_BUSY_ERRORS=FALSE
REM SET NSR_PROCESS_ENVIRON=TRUE
REM SET NSR_SAVESET_NAME=ssName
REM
REM ===============================================================
REM Temporary files
REM ===============================================================
REM
SET DBCCBAT=%tmp%\nsrdbcc.bat
SET NSREDCMD=%tmp%\nsredcmd.tmp
REM
REM ***************************************************************
REM ***************************************************************
REM DO NOT CHANGE AFTER THIS LINE
REM ***************************************************************
REM ***************************************************************
REM
REM ===============================================================
REM Get command line arguments
REM ===============================================================
REM
SET nsrArgs=
SET prevArg=PREVARG
:ArgLoop
if "%1" == "" GOTO Backup
SET nsrArgs=%nsrArgs% %1
IF "%DBCCOPT%" == "" GOTO NextArg
ECHO %1 | FIND /i "MSSQL:" > nul
IF ERRORLEVEL 1 GOTO NextArg
REM
REM ===============================================================
REM If previous argument is -N, then
REM this is the save set name.
REM If previous argument is -g, then
REM this is the group name.
REM ===============================================================
REM
IF %prevArg% == -N GOTO NextArg
IF %prevArg% == -g GOTO NextArg
REM
REM ===============================================================
REM Found a database name. Construct
REM sqlmaint command in a batch file
REM ===============================================================
REM
ECHO %DBCCCMD% -D %1 -Rpt %DBCCRPT% %DBCCOPT% > %DBCCBAT%
REM
REM ===============================================================
REM Remove MSSQL: from db name in
REM the batch file
REM ===============================================================
REM
ECHO 1rMSSQL:> %NSREDCMD%
ECHO 1rmssql:>> %NSREDCMD%
ECHO e >> %NSREDCMD%
EDLIN %DBCCBAT% < %NSREDCMD% > nul
REM
REM ===============================================================
REM Do DBCC
REM ===============================================================
REM
REM TYPE %DBCCBAT%
CALL %DBCCBAT% > nul
IF ERRORLEVEL 1 GOTO DbccErr
REM
REM ===============================================================
REM Shift to next argement
REM ===============================================================
REM
:NextArg
SET prevArg=%1
SHIFT
GOTO ArgLoop
REM
REM ===============================================================
REM Do actual backup here
REM ===============================================================
REM
:Backup
SET BACKUPCMD=%NSRPATH%nsrsqlsv.exe %NSRSQLOPT% %nsrArgs%
REM ECHO %BACKUPCMD%
%BACKUPCMD%
REM
GOTO Exit
:DbccErr
ECHO DBCC failed. Please see %DBCCRPT%(_YYYYMMDD) for detail.
REM
REM ===============================================================
REM Exit here
REM ===============================================================
REM
:Exit
ENDLOCAL
@ECHO ON
|