| Title: | *OLD* ALL-IN-1 (tm) Support Conference |
| Notice: | Closed - See Note 4331.l to move to IOSG::ALL-IN-1 |
| Moderator: | IOSG::PYE |
| Created: | Thu Jan 30 1992 |
| Last Modified: | Tue Jan 23 1996 |
| Last Successful Update: | Fri Jun 06 1997 |
| Number of topics: | 4343 |
| Total number of notes: | 18308 |
Hello,
With the upcoming migration to WordPerfect in mind I've created a little
utility which converts all existing WPS-PLUS VAX/VMS document for a user to
WordPerfect VAX/VMS documents.
This utility (see .1) doesn't need KEYpak or CDA convertor library.
Instead it uses an undocumented WordPerfect convertor utility.
$ WP51/CONVERT=DOCUMENT/FROM=WPL <wpl-doc> <wpc-doc>
The value WPL in the FROM qualifier isn't documented !!
Utility description:
WPS-PLUS VAX/VMS to WordPerfect VAX/VMS Convertor
=================================================
This convertor converts all existing WPS-PLUS VAX/VMS documents
to WordPerfect VAX/VMS documents.
This procedure should be executed in the user's WPS-PLUS directory
The converted documents can be found in the WPCORP directory which
is located in the user's login directory.
The name of the converted document is made up by taking the original
WPS-PLUS document number and adding the extension ".WPC", e.g.
000399.WPC.
The file INDEX.TXT in the above mentioned WPCORP directory can
help to relate the current WordPerfect filename to its
original WPS-PLUS folder/title counterpart.
Regards,
Martin
p.s In a few weeks I'll start to develop an utility for the ALL-IN-1 WPS-PLUS
users.
This utility will convert a whole folder/drawer containing WPS-PLUS
documents to WordPerfect documents.
| T.R | Title | User | Personal Name | Date | Lines |
|---|---|---|---|---|---|
| 4269.1 | The utility | UTRTSC::SMEETS | X-WING rookie | Fri Jun 17 1994 08:54 | 72 |
$! WPS_CNV_WPC.COM
$!
$ set term/width=80
$!
$ Type sys$input
WPS-PLUS VAX/VMS to WordPerfect VAX/VMS Convertor
=================================================
This convertor converts all existing WPS-PLUS VAX/VMS documents
to WordPerfect VAX/VMS documents.
This procedure should be executed in the user's WPS-PLUS directory
The converted documents can be found in the WPCORP directory which
is located in the user's login directory.
The name of the converted document is made up by taking the original
WPS-PLUS document number and adding the extension ".WPC", e.g.
000399.WPC.
The file INDEX.TXT in the above mentioned WPCORP directory can
help to relate the current WordPerfect filename to its
original WPS-PLUS folder/title counterpart.
$ inquire t " Press return to continue"
$ set term/width=80
$ write sys$output "Checking current directory ...."
$ if f$extract(f$length(f$directory())-8,7,f$directory()) .NES. "WPSPLUS" -
then goto invalid
$!
$
$ if f$search(F$TRNLNM("SYS$LOGIN")+"WPCORP.DIR") .eqs. ""
$ then
$ wp_dir = F$trnlnm("SYS$LOGIN")- "]" + ".WPCORP]"
$ create/dir/log 'wp_dir
$ endif
$ wp_dir = F$trnlnm("SYS$LOGIN")- "]" + ".WPCORP]"
$ index = wp_dir + "INDEX.TXT"
$!
$ open/read docdb docdb.dat
$ open/write output 'index
$ loop:
$ read/index=2/end_of_file=close_all docdb record
$ Folder = f$extract(0,30,record)
$ Title = f$extract(113,70,record)
$ File = f$extract(48,20,record)
$ docnum = f$string(1000000-F$integer(F$extract(36,6,record)))
$ zero_loop:
$ if f$length(docnum) .LT. 6
$ then
$ docnum = "0" + docnum
$ goto zero_loop
$ endif
$ wpc_file = wp_dir+docnum+".wpc"
$ write output docnum," ",folder," ",title
$ write sys$output "Processing document (",docnum,") in folder ",folder
$ wp51/convert=document/from=wpl 'file 'wpc_file
$ goto loop
$!
$ close_all:
$ close docdb
$ close output
$!
$ sort 'index 'index
$ pu/nolog 'index
$ exit
$!
$ invalid:
$ write sys$output ""
$ write sys$output -
"This command procedure should be executed in the user's WPSPLUS directory..."
$ exit
| |||||