| T.R | Title | User | Personal
Name | Date | Lines |
|---|
| 2525.1 | | BUSHIE::SETHI | Man from Downunder | Mon Apr 05 1993 05:35 | 10 |
| Hi Mike,
>When a user answers a mail message, they receive their own reply. This
>is a multi-node environment.
This is how it's suppose to work !!!
Regards,
Sunil
|
| 2525.2 | Expanding.... | IOSG::PYE | Graham - ALL-IN-1 Sorcerer's Apprentice | Mon Apr 05 1993 11:49 | 23 |
| Re .1,
Well maybe :-)
Re .0
1) When you answer a message, it goes into your OUTBOX.
2) If you asnwer a message that someone off-node (i.e. outside your
cluster) sent to you, then (as a result of a bug in my opinion!) you
get added to the addresses and receive a copy. Look at the message in
the OUTBOX, and see if your name is there with an address like:
Your Name ( YOURACCOUNT @ A1 @ YOURNODE )
If so, you can remove it from the address list using the MH command
before you send the message.
3) If one of the people you are mailing has their Mail Destination set
to VMSMAIL, and you have VMSmail set to auto copy self, then you'll get
a copy of your reply back from VMsmail.
Graham
|
| 2525.3 | Wow, Your Right. | KXOMAA::ALLEY | MIKE ALLEY @KXO | Mon Apr 05 1993 15:03 | 8 |
| I just tested this. Your correct. I had never really seen this before, 'cause
I typically just respond to the Sender.
This has to be some kind of bug. Someone has had to complain about this before.
Thanks for the input.
Mike
|
| 2525.4 | Expect the expected | WARNUT::RICE | It's only meeeeee | Mon Apr 05 1993 16:04 | 23 |
| I never thought it was a bug myself - just the expected behaviour.
I must admit this has caused me grief on several occasions, I've usually
just hidden behind the official "Expected Behaviour" statement in a STARS
article I found. Here is the text (I've just rediscovered it while
writing this note !)
***
This is the normal expected behaviour of the ALL-IN-1 product and
arises because the mail is received from a remote system via message
router. ALL-IN-1 has no simple way of determining that one address of
many in a distribution list being replied to is actually the user replying
to the mail (the problem should not arise with local mail).
The action is coded into ALL-IN-1 as part of the MAIL function -
specifically "MAIL ANSWER". It was originally documented as long ago
as the ALL-IN-1 V2.1 release notes.
A workaround is to use the MH option to remove your own name from
the distribution list after creation.
***
Steve.
|
| 2525.5 | Annoying, but just too hard to fix.... | IOSG::PYE | Graham - ALL-IN-1 Sorcerer's Apprentice | Tue Apr 06 1993 09:52 | 12 |
| My position on this is that it's an annoying behavioural feature, but
since I'm part of the development group and I know it would be hard to
fix properly, I just put up with it. One day, when we are all
registered in X500, it will be possible to absolutely identify whether
a particular address correpsonds to oneself or not, and hence we could
fix this.
Graham
PS Meanwhile, in the next reply is a UDP (from the keyboard of the
departed Don V.) which will remove easily identifiable versions of
yourself from the address list.
|
| 2525.6 | PURGE_SENDER.SCP | IOSG::PYE | Graham - ALL-IN-1 Sorcerer's Apprentice | Tue Apr 06 1993 09:56 | 79 |
| ! PURGE_SENDER.SCP Purge sender from mail message
!
! This script purges the sender from receiving the current mail message.
!
! If the user appears in the list of TOs or CCs she/he/it is prompted to
! determine whether they wish a copy. If so all but a single copy of their
! name is stripped from the list. If they do not wish a copy then all
! occurrences of their name are stripped.
!
DECIMAL I
GET #COUNT = 0
GET #TOTAL = 0
!
! Verify that this is an UNSENT message
!
.IF CAB$.MAIL_STATUS[OA$CURMES] NES "UNSENT" THEN .GOTO NOT_UNSENT
!
! Search for any TOs for this user
!
FOR CAB$ATTRIBUTES:"TO" WITH .VALUE <=> OA$USER DO -
COMPUTE #COUNT = #COUNT + 1 \\ GET #USER = .VALUE
!
! If any found then mark and ask for action
!
.IF #COUNT EQ 0 THEN .GOTO CHECK_CC
GET #TOTAL = #COUNT
YESNO_PROMPT "You are on the list of receivers. Do you wish to remain? "
OA$FLD_STAY
!
.IF OA$PROMPT_TEXT:1 <=> "Y" AND #COUNT GT 1 THEN -
COMPUTE #COUNT = #COUNT - 1
!
! Delete the required number of TOs
!
.LABEL DELETE_TO
!
.IF #COUNT LE 0 THEN .GOTO CHECK_CC
CAB DELETE_ATTRIBUTE OA$CURMES, "TO", #USER
COMPUTE #COUNT = #COUNT - 1
.GOTO DELETE_TO
!
! Now check the CC list
!
.LABEL CHECK_CC
FOR CAB$ATTRIBUTES:"CC" WITH .VALUE <=> OA$USER DO -
COMPUTE #COUNT = #COUNT + 1 \\ GET #USER = .VALUE
!
! Take action based on any TOs or CCs found
!
.IF #COUNT EQ 0 THEN .GOTO FINI
COMPUTE #TOTAL = #TOTAL + #COUNT
.IF #TOTAL GT 0 THEN .GOTO DELETE_CC
!
YESNO_PROMPT "You are on the list of receivers. Do you wish to remain? "
OA$FLD_STAY
!
.IF OA$PROMPT_TEXT:1 <=> "Y" AND #COUNT GT 1 THEN -
COMPUTE #COUNT = #COUNT - 1
!
! Delete the required number of CCs
!
.LABEL DELETE_CC
!
.IF #COUNT LE 0 THEN .GOTO FINI
CAB DELETE_ATTRIBUTE OA$CURMES, "CC", #USER
COMPUTE #COUNT = #COUNT - 1
.GOTO DELETE_CC
!
! This isn't UNSENT so we don't want to work on it
!
.LABEL NOT_UNSENT
DISPLAY This message is not UNSENT. No action taken.
.EXIT
!
! Normal exit by informing the number in the list
!
.LABEL FINI
GET OA$DISPLAY = "There were " #TOTAL " occurrence(s) of your name in this distribution."
.EXIT
|