Conference iosg::all-in-1_v30

1950.0. "TM I, select all events and XD loops in TMSEVXD.SCP" by KAOT01::M_MORIN (Le diable est aux vaches!) Fri Dec 11 1992 19:27

There appears to be a problem with the script TMSEVXD.SCP.  At the place where
it checks

 .if *CAL.TYPE:U[#RFA] ne. 'M' then .goto LOOP

if this record is not an appointment or a meeting, it assumes "something is
bad - don't touch it" and goes back to the LOOP.  The loop gets the next RFA
which ends up being the same as the last time in the loop.  Hence the loop.

Under what conditions would a calendar record in USERNAME.A1CAL have an event
type of ' ' (blank)?

This is currently happening at a customer site but we haven't been able to 
isolate yet why the event types are blank.

Any help appreciated.

Loop in TMSEVXD.SCP is indicated below.

Mario

                               TMSEVXD.SCP
===============================================================================
! TMSEVXD.SCP	Time Management Scrolled Event Multiple Delete Script
!
! This script will delete multiply selected events from a scrolled region.

!check that something was selected
    .IF OA$SCROLL_SELECTED EQS "0" THEN .GOTO NONE_SELECTED

!! always ask to delete since events aren't put in wastebasket
	YESNO_PROMPT OA$_TM_DEL_ALL_EVENTS \OA$FLD_STAY
	.IF OA$PROMPT_DISPOSE NES "2" THEN .EXIT

    GET #CONFID = ""
    GET OA$DISPLAY = OA$_GBL_WORKING\FORCE
    GET #SAVE_TYPE = #TM_TYPE
    GET #SAVE_DATE = #CAL_MTNG_WHEN
    GET #SAVE_TIME = #CAL_MTNG_STIME
    GET #SAVE_DESC = #CAL_MTNG_DESC
.LABEL LOOP      <--------------------------------------------------------------|
    GET #RFA = ''								|
    NEXT_SELECTED OA$SCROLL_BINDING, #RFA					|
    .IF #RFA EQS '' THEN .GOTO EXIT_PROCEDURE					|
    .IF OA$STATUS EQS "0" THEN .GOTO EXIT_PROCEDURE				|
										|
  !Get the key value, event type, and scheduler.				|
    get #K = *CAL.CAL_KEY[#RFA]							|
    get #MTG_PTR = *CAL.MEETING_POINTER[#RFA]					|
										|
!check if user did set owner and this is confidential				|
	.IF *CAL.CONFIDENTIAL[#RFA] EQS OA$Y AND -				|
		OA$USER NES OA$TM_OWNER THEN .GOTO CONFID			|
										|
!If its not an appointment or a meeting, something is bad - don't touch it!	|
   .if *CAL.TYPE:U[#RFA] EQS 'A' then .goto APPOINTMENT                    	|
   .if *CAL.TYPE:U[#RFA] nes 'M' then .goto LOOP           <--------------------|

!    GET #CAL_MEETING_POINTER = *CAL.MEETING_POINTER[#RFA]
    CAL DISPLAY MEETING #K
    CAL CAN MEET
    .if OA$MSG_SEV EQS "I" then -
      OA$SCL_REMOVE #RFA -
    else -
      OA$SCL_DESELECT #RFA
    .GOTO LOOP

.LABEL APPOINTMENT
    WRITE DELETE *CAL %KEY = #K    
    .GOTO LOOP

.LABEL CONFID
    GET #CONFID = OA$Y
    OA$SCL_DESELECT #RFA
    .GOTO LOOP

.LABEL NONE_SELECTED
    GET OA$DISPLAY = OA$_INXNONESEL\FORCE
    .EXIT

.LABEL EXIT_PROCEDURE
    OA$SCL_REFRESH
    GET #CAL_MTNG_WHEN = #SAVE_DATE
    GET #CAL_MTNG_STIME = #SAVE_TIME
    GET #CAL_MTNG_DESC = #SAVE_DESC
    GET #TM_TYPE = #SAVE_TYPE
    .IF #TM_TYPE EQS 'A' THEN CAL DISP APP 
    .IF #TM_TYPE EQS 'M' THEN CAL DISP MEET
! This display is to get rid of the working message
     DISPLAY
    .IF #CONFID EQS OA$Y THEN GET OA$DISPLAY = OA$_TM_NOT_WITH_CONFID\FORCE
    .EXIT

        Hi Mario,
        
        There are no documented circumstances that will produce the
        results you are describing.  I've seen it myself, so I know it's
        possible.  I'd submit 2 SPR's so that both problems get fixed.
        
        Dave Zaniewski