[Search for users] [Overall Top Noters] [List of all Conferences] [Download this site]

Conference iosg::all-in-1_v30

Title:*OLD* ALL-IN-1 (tm) Support Conference
Notice:Closed - See Note 4331.l to move to IOSG::ALL-IN-1
Moderator:IOSG::PYE
Created:Thu Jan 30 1992
Last Modified:Tue Jan 23 1996
Last Successful Update:Fri Jun 06 1997
Number of topics:4343
Total number of notes:18308

1810.0. "fill in a form, without displaying it" by KAOFS::D_STREET () Wed Nov 18 1992 20:12

    Hello,
     I have a client who would like to fill in a form, without displaying
    it. What they want to do is to be able to automatically fill in
    attendees for a meeting, without displaying the form. He is currently
    doing it with a UDP, but the form is seen on the screen. 
    
     We at the Canadian CSC have been told not to get involved with "How
    to" questions (because it is consulting), but this is a DEC emplyee on
    site. I am not allowed to do the research, but if there is a known way,
    I can pass it along.
    
    
    							Thanks
    
    							Derek Street
T.RTitleUserPersonal
Name		DateLines
1810.1Just write to the entry form ..OCTAVE::VIGNEAULTJava-ManThu Nov 19 1992 12:5514
    
    
    I would think the write command would work in this case.  It allows
    you to directly write a record to a file mapped by an entry form.
    
    Syntax is:
    
    WRITE mode entry-form-name key=value, field=value
    
    for example,
    
    WRITE ADD MY_ENTRY_FORM KEY="John Doe", Street="EASY", PHONE="111-1111"
    
    Regards, Larry
1810.2Creating attendee records behind the scenesSIOG::T_REDMONDThoughts of an Idle MindThu Nov 19 1992 15:02103
    What version of ALL-IN-1 are you dealing with?
    
    If you want to create attendees for a meeting in the background you'll
    have to use some of the CALENDAR functions to create the meeting and
    then populate the scroll data set used for the attendee details.  I
    think this changed slighly between V2.4 and V3.0.  Frank Nicodem posted
    a script elsewhere in this conference which might shed some light, but
    here's a script that I have used to illustrate how to create a meeting
    for the members of a group...
    
!+
!	TM_GS_MEETING.SCP
!+

.LABEL START

	CALENDAR INIT FILES
	GET OA$DISPLAY = OA$_GBL_WORKING \FORCE

	GET #ABORT = #DRAWER_SWITCH = #ATTENDEE_PRESENT = 0

	.IF OA$MAIL_CURDWR NES OA$MAIL_DRAWER
	.THEN
 	    ! Not positioned in the MAIN drawer - switch over
	    GET #DRAWER_SWITCH = 1
	    GET #PRV_DRAWER = OA$CURDWR
	    CABINET SET_DRAWER OA$MAIL_DRAWER
            .IF OA$STATUS EQ 0
            .THEN
                GET #ABORT = 1
            .END_IF
	.END_IF

	.IF #ABORT EQ 1 THEN .GOTO CANT_GO_TO_MAIN

!	Initialize a dummy TM message 
	CALENDAR MAIL_INIT

	FOR GROUP$:"ENGINEERS" DO -
         GET #MEMBER_NAME = .%KEY\\ - 
	 .IF PROFIL.USER[#MEMBER_NAME] NES "" -
	  THEN -
            GET #ATTENDEE = PROFIL.FULNAM:37[#MEMBER_NAME] "(" #MEMBER_NAME ")"\\-
	    CABINET ADD_ATTRIBUTE , "TO", #ATTENDEE

!	Check that we have at least one attendee

	FOR FIRST CAB$ATTRIBUTES:TO DO GET #ATTENDEE_PRESENT = 1
	.IF #ATTENDEE_PRESENT EQ 0 THEN .GOTO NO_ATTENDEES

!	All the attendees have been added to the dummy message. 
! 	Set up some symbols for the meeting

	GET #CAL_MTNG_DESC      = "Another test of meeting creation"
	GET #CAL_MTNG_WHEN      = OA$DATE_FULL
	GET #CAL_MTNG_STIME     = "07:21pm"
	GET #CAL_MTNG_ETIME     = "07:23pm"
	GET #CAL_MTNG_CONFID    = OA$N
	GET #CAL_MTNG_SCHEDULER = OA$USER
	GET #CAL_MTNG_LOC       = "Conference room 1"
	GET #CAL_MTNG_PRIORITY  = "A1"

	CALENDAR SCHEDULE MEETING
	.IF OA$STATUS EQ 0 THEN .GOTO NOT_SCHEDULED	

.LABEL RESET_DRAWER

	! And switch back to the previous drawer, if necessary

	.IF #DRAWER_SWITCH EQ 1
	.THEN
	    CABINET SET_DRAWER #PRV_DRAWER
	.END_IF
	
.LABEL ALL_DONE

	DISPLAY Meeting scheduled and notices sent!
	.EXIT

.LABEL CANT_GO_TO_MAIN

	DISPLAY Unable to create meeting message in MAIN drawer
	.EXIT

.LABEL NO_ATTENDEES

	! No attendees could be found

.LABEL NOT_SCHEDULED
	! Clean up the dummy message

	.IF #DRAWER_SWITCH EQ 1
	.THEN
	    CABINET SET_DRAWER #PRV_DRAWER
	.END_IF

	CALENDAR MAIL_DELETE
	GET OA$TM_SEND_MAIL = 0
	DISPLAY An error occurred when scheduling the meeting
	.EXIT

!	Script to create a time management meeting from for an ALL-IN-1 group
1810.3sorry, I should have given the versionKAOFS::D_STREETWed Nov 25 1992 23:166
    I am really sorry for not including the version of ALL-IN-1, because it
    is 2.4, and the above 3.0 script is not quite working. Can someone
    suggest the modifications that would be required? 
    
    							Derek Street.
    (PS. Thanks for the help so far Tony.)
1810.4Help wanted !!!!!TRCOA::SHEUFred Sheu @TRCThu Dec 03 1992 17:1333
The following note is put up on behalf of Bob McGuire. He is currently working
at the customer site and fighting with this problem. Anybody out there has any
idea about solving Bob's problem, please give him a shout at 416-314-6588
(call collect). 
=============================================================================


I have tried to schedule an meeting without displaying the SCHEDMA form, based
on your code. However, I am running V2.4, which does not have those calendar
functions.

After calling SCHEDMUIB to get calendar info, I try to populate
CAL$SCROLL_ATTENDEES using the following command:

	.FZ WRITE AND CAL$SCROLL_ATTENDEES NUMBER=1, TEXT="NO_ATTENDEES"

Then I call SCALENDAR SCHEDULE MEETING

This will schedule the meeting but when you read it, there are no attendees
listed, and consequently, when you edit this meeting, it deletes the meeting
and says YOU MUST HAVE SOMEONE TO MEET WITH.

The only way I caould make it work is to write to CAL$SCROLL_ATTENDEES, call
CAL SCH MEET, then write to CAL$SCROLL_ATTENDEES again and call CAL RESCH MEET.

This approach, however will not work with Schedule Recurring Events.

Could you please tell me what I'm missing when I try to schedule the meeting
the first time.

Thanks, Bob.
1810.5Scheduling a V2.4 meeting without any UISIOG::T_REDMONDThoughts of an Idle MindFri Dec 04 1992 10:4042
.LABEL START
        ! A script to schedule a meeting without any forms being displayed
        ! This only works for V2.4 or earlier, because V3.0 uses EM data
        ! sets instead of CAL$SCROLL_ATTENDEES
    
        ! Initialize TM, just to be sure
	CALENDAR INIT FILES
        ! Initialize the TM meeting variables which we need to provide
        ! data for the dummy meeting -- these symbols could be set from
        ! an ARG form or data file
	GET #CAL_MTNG_DESC = "Testing Behind-the-scenes Meeting creation"
	GET #CAL_MTNG_WHEN = "25-Dec-1992"
	GET #CAL_MTNG_STIME = "07:40a"
	GET #CAL_MTNG_ETIME = "07:41a"
		GET #CAL_MTNG_CONFID = OA$N
	GET #CAL_MTNG_SCHEDULER = OA$USER
	GET #CAL_MTNG_LOC = "Meeting Room 1"
	GET #CAL_MTNG_PRIORITY = "A1"
        ! Put us at the right date, not strictly necessary, but nice to do
	CALENDAR SET DATE #CAL_MTNG_WHEN
        ! Clear CAL$SCROLL_ATTENDEES
	CALENDAR CLEAR ATTENDEE
        ! Prepare the mail address of the people we want to meet with. Note
        ! that each address must be formatted correctly
	GET #ATTENDEE_ADDRESS = "Tony Redmond"
	GET #ATTENDEE_ADDRESS = #ATTENDEE_ADDRESS:37 "( REDMOND@A1@DUBSWS )"
        ! Write our formatted address into the CAL$SCROLL_ATTENDEES data
        ! set.
	WRITE ADD CAL$SCROLL_ATTENDEES NUMBER = "1", TEXT = #ATTENDEE_ADDRESS
        ! We could loop at this point to go and collect all the other names
        ! for the meeting, but I'll just proceed here...
	CALENDAR SCHEDULE MEETING
        ! Of course, I must check OA$STATUS    .... ;-)
	.IF OA$STATUS NE 1 THEN .GOTO NOT_SCHEDULED
	.EXIT

.LABEL NOT_SCHEDULED

	DISPLAY Meeting not scheduled
	.EXIT