[Search for users] [Overall Top Noters] [List of all Conferences] [Download this site]

Conference iosg::all-in-1_v30

Title:*OLD* ALL-IN-1 (tm) Support Conference
Notice:Closed - See Note 4331.l to move to IOSG::ALL-IN-1
Moderator:IOSG::PYE
Created:Thu Jan 30 1992
Last Modified:Tue Jan 23 1996
Last Successful Update:Fri Jun 06 1997
Number of topics:4343
Total number of notes:18308

1380.0. "MHP SDA error" by KERNEL::SMITHERSJ (Living on the culinary edge....) Wed Sep 09 1992 11:42

I'm confused.....

A customer reported this problem on ALL-IN-1 v.3.0 with SDA which I 
can reproduce but I have spent so long trying to go through the 
various scripts and command files, that I can't work out where the
error is coming from.  Can anyone help please?

If I run SDA from MHP with a restart, I get the following error in 
the log SHUTDOWN_ALL-IN-1_SM.LOG1992090817500000;1.

OA$LIB:SM_SHUTDOWN.COM, SM_SHUTDOWN.SCP and SMJACKET.COM seem to be
the culprits somewhere but I can't for life of me work out where.

Can someone shed any light on this?

Thanks
Julia UK CSC


![IO]     Closing TXT$TXL_DO, File: DISK$FTAPPS:[ALLIN1.LIB_SHARE]SM_SHUTDOWN.SC
!               P;
%OA-W-TRAVIEW, Trace option TERM requested, use VIEW TRACE to see output
%OA-I-SHUT_NOTIFIED, All users have been notified of the shutdown
![FLOW]   Undisplaying all workspaces
![INPUT]  Prompt value:
![FLOW]   Undisplaying all workspaces
$       0
$ unexpected_error:
$       status = $status
$       wo "E unexpected error condition"
%SM_SHUTDOWN-E unexpected error condition
$       error_msg = f$message(status)
$       error_msg[0,1]:="-"
$       write sys$output "-CLI-W-IVVERB, unrecognized command verb - check vali
                                                                       
-CLI-W-IVVERB, unrecognized command verb - check validity and spelling
$       status = 2
$       goto  cleanup
$ cleanup:
$       1
$       set message /NOFACILITY/NOSEVERITY/NOIDENTIFICATION/NOTEXT
$       wo "I-DONE processing complete for %SM_SHUTDOWN"
%SM_SHUTDOWN-I-DONE processing complete for %SM_SHUTDOWN

.....


$!
$! V2.4-001 Exit with status that of the utility command file
$!
$       status = util_status
$       if .not. status then goto utility_error
$ utility_error:
$       wo "E- Internal error in housekeeping procedure"
%SMJACKET-E- Internal error in housekeeping procedure
$       error_text = "SM$_JKT_INTERNAL_ERROR"
                                                                                



    
T.RTitleUserPersonal
Name
DateLines
1380.1repeated hereIOSG::TYLDESLEYThu Sep 10 1992 12:598
    Julia,
    Thanks for reporting this. I was able to replicate this almost exactly
    last night on our system.  I think I have traced the cause of the
    problem back to sm_shutdown.scp, but need to do some further testing
    this afternoon. I have also checked through the TIME database, and it 
    doesn't seem to have been reported. I think an SPR is required.
    Cheers
    DaveT                      
1380.2number of problemsIOSG::TYLDESLEYFri Sep 11 1992 10:149
    Julia,
    There seem to be a number of problems here with the restart. Amongst
    these are the symbol #sh_restart not being correctly set, a spurious
    comma in SM_SHUTDOWN.SCP and some lines commented out in the same
    script, with no obvious reason. I have tested a modified script last
    night, and it worked OK, so I would appreciate it if you could submit
    an SPR so that I can get it fixed.
    Cheers
    DaveT
1380.3I'll do thatKERNEL::SMITHERSJLiving on the culinary edge....Fri Sep 11 1992 10:246
    Thanks Dave for testing this out.  I'll submit an SPR but in the
    meantime, is there any modifications I can give to the customer 
    for a tidier shutdown and restart?
    
    Thanks
    julia
1380.4try thisIOSG::TYLDESLEYFri Sep 11 1992 10:57168
Julia,

Extract the script below and ask them to place it in the site OA$LIB. It is
the one I used for testing last night, and carries absolutely no guarantees!
They then need to schedule the shutdown via SDA, noting the time for which
it was set. 

Next, from within System Management, call the SH Utility Master file
SM_SH_SCHEDULE, and do a Find on the schedule identifier, by virtue of its
NBS time. Having identified the correct job, edit the field OASH_RESTART: to
a 1, in order to set the #SH_RESTART symbol to 1, later. Close the Utility 
Master File, and then wait for the job to run. The result should be that 
ALL-IN-1 should shut down cleanly and restart correctly, but you will still
get some messiness in the shutdown log, and it is this that I want to work on
when we do the fix. Also, they will still get a Housekeeping Exception report,
but I believe this is normal and is caused by the internal errors from 
SMJACKET that you will find recorded in the log file. I want to investigate
these further as well.

Hope this helps. Please let me know how it goes. Extract script from ===== 
line onwards.
DaveT

=============================================================================

! SM_SHUTDOWN.SCP				 VX.X-001
!
!----------------------------------------------------------------------------
SET_TRACE (SYMBOL,SCRIPT,LOG='SYS$OUTPUT')

        GET OA$DCL='set command oalib:a1submit.cld'
	GET #batch_a1 = sm_policies.batch_accnt["SYSTEM"]
	GET #batch_vms = profil.vmsusr[#batch_a1]

	OA$FLO_OPEN oa$site_lib:sitemanager
	OA$FLO_OPEN oa$lib:manager
	GET #sh_restart = 0
	GET #dcl_status = 0
	GET #job_name = "Restart ALL-IN-1"
	GET #file_name = "OA$" oa$user "_AUTO_RESTART"
	MAKE_FILE #log_file, #file_name
	GET #log_name = "OA$LOG:" #log_file ".LOG"


	GET #scheduler = sm_sh_schedule.sa_util_sched_by[cli$nbs_run_time]
	GET #queue_name = sm_sh_schedule.sa_util_queue[cli$nbs_run_time]
	GET #sh_reason  = sm_sh_schedule.oash_reason[cli$nbs_run_time]
	GET #sh_restart = sm_sh_schedule.oash_restart[cli$nbs_run_time]


	GET #sh_restart_time = sm_sh_schedule.oash_restart_time[cli$nbs_run_time]
	DATE_CONVERT #sh_restart_nbs, #sh_restart_time, 7
	DATE_CONVERT #sh_restart_vms, #sh_restart_time, 0

	GET #sh_freq_value   =  sm_sh_schedule.sa_util_frq[cli$nbs_run_time]
	GET #sh_freq = 0
	.IF #sh_freq_value NES '' THEN GET #sh_freq = FN$TRIM(#sh_freq_value)
	
!+
! Shutdown the filecabinet servers
!-
	DO oa$lib:sm_fc_server_stop
!+
! Kick users off and shut the main image down
!-
	GET #sh_down_now = oa$date_full " " oa$time
!***
!	SHUTDOWN #sh_down_now, #sh_reason, #sh_restart_time,
!***
	SHUTDOWN #sh_down_now, #sh_reason, #sh_restart_time

!+
! If all has been successfully shutdown then queue the restart job
! - if requested
!-
	.IF #sh_restart EQ 1 AND -
		(#sh_restart_time NES '') 
        .THEN 
	    .TEXT "Queueing restart job ..."
		GET OA$DCL='a1submit/noprint/noidentify-'
		GET OA$DCL='/after=' """" #sh_restart_vms """" '-'
	        GET OA$DCL='/name="' #job_name '"/queue=' #queue_name ' -'
	        GET OA$DCL='/log_file=' #log_name '-'
	        GET OA$DCL='/user=' #batch_vms '/parameters= -'
		GET OA$DCL='("' #batch_a1 '",-' 
		GET OA$DCL='"' cli$a1_account_pass '",- '
	        GET OA$DCL='"' #scheduler '")-'
	        GET OA$DCL=' oa$lib:sm_restart'
	        GET OA$DCL= -
	        "write oamailbox ""OA GET #dcl_status = ''f$int($status)'"""
		GET OA$DCL='@dclmailbox'
	.END_IF

	.IF #dcl_status THEN GET cli$shut_status = 1 -
	ELSE .GOTO submit_failed

!+
! If cyclical shutdown then reset the restart date
!-
	.IF #sh_freq EQ 0 THEN .GOTO finish 


	GET #vms_delta = #sh_freq "-00:00"
!+
! convert nbs to vms to use a command procedure to increment the time by the
! frequency 
!-
	DATE_CONVERT #vms_run_time , #sh_restart_time, 0
	GET #vms_run_time = #vms_run_time:11 ":" #vms_run_time:11:12
!+
! ... and use the command file to add
!-
	GET OA$FUNCTION = -
	'COMMAND oa$lib:sm_add_time "' #vms_run_time '" "' #vms_delta '"'

!+
! save the result and write back to the schedule record
!- 
	GET #vms_run_time = #result
	DATE_CONVERT #resked_start_time, #vms_run_time,10

	WRITE CHANGE sm_sh_schedule sa_util_sched = cli$nbs_resked_time,-
		 oash_restart_time = #resked_start_time 



.LABEL fc_shut_failure
	GET cli$shut_status = 2
	.GOTO finish

.LABEL main_shut_failure
	GET cli$shut_status = 3
	.GOTO finish

.LABEL submit_failed
	GET cli$shut_status = 4
	.GOTO finish

.LABEL finish

	.exit

!
!-------------------------------------------------------------------------
! COPYRIGHT (c) 1990,1991,1992 BY
! DIGITAL EQUIPMENT CORPORATION, MAYNARD, MASSACHUSETTS.
! ALL RIGHTS RESERVED.
!
! THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY BE USED AND COPIED
! ONLY  IN  ACCORDANCE  OF  THE  TERMS  OF  SUCH  LICENSE  AND WITH THE
! INCLUSION OF THE ABOVE COPYRIGHT NOTICE. THIS SOFTWARE OR  ANY  OTHER
! COPIES THEREOF MAY NOT BE PROVIDED OR OTHERWISE MADE AVAILABLE TO ANY
! OTHER PERSON.  NO TITLE TO AND  OWNERSHIP OF THE  SOFTWARE IS  HEREBY
! TRANSFERRED.
!
! THE INFORMATION IN THIS SOFTWARE IS  SUBJECT TO CHANGE WITHOUT NOTICE
! AND  SHOULD  NOT  BE  CONSTRUED  AS A COMMITMENT BY DIGITAL EQUIPMENT
! CORPORATION.
!
! DIGITAL ASSUMES NO RESPONSIBILITY FOR THE USE  OR  RELIABILITY OF ITS
! SOFTWARE ON EQUIPMENT WHICH IS NOT SUPPLIED BY DIGITAL.
!
!-------------------------------------------------------------------------
!+
! Parameters:
!
!	cli$nbs_resked_time
!-

1380.5Worked fineKERNEL::SMITHERSJLiving on the culinary edge....Fri Sep 11 1992 12:349
    Dave
    
    Yes, that worked fine on our system.  I won't give that to the
    customer though unless he really wants it as I don't want him
    to start editing SM_SH_SCHEDULE.
    
    Thanks and I'll raise the SPR.
    
    julia
1380.6What's new in this area ???BIS10::COLLARTTue Jun 01 1993 10:2420
		Hello,


	I get a new call concerning this problem but I cannot 
	find any information on a real solution......


	My colleague Veerle Laroche enter an SPR for that  
	around 12-Jan-93.


	Is a solution exists or do we have to live with the 
	workaround of Dave that cannot be performed by any customer?



				Thanks for help

				Eric.
1380.7this isn't for SPR updatesAIMTEC::WICKS_AAlphatraz - Coming Summer 93Tue Jun 01 1993 18:228
    Eric,
    
    this isn't a formal support channel so if you need information on the
    status of an SPR please contact the IOSG support group directly.
    
    regards,
    
    Andrew.D.wicks
1380.8mend SM_SHUTDOWN.COMIOSG::VOWLESRaphael VOWLES DTN 830 6910 REO2 G/M2Wed Jun 23 1993 15:1726
re: .0   You get the errors ecause of a syntax error in SM_SHUTDOWN.COM.
         The fix below removes the cause of the error/s.

>>>> %SM_SHUTDOWN-E unexpected error condition
>>>> -CLI-W-IVVERB, unrecognized command verb - check validity and spelling
>>>> %SM_SHUTDOWN-I-DONE processing complete for %SM_SHUTDOWN
>>>> %SMJACKET-E- Internal error in housekeeping procedure


WORKAROUND: Use Customization Management to modify element SM_SHUTDOWN.COM
    as follows:

>>> The section of code that reads:

$ cleanup:
$       'f$verify(save_ver)



>>> should be modified to read:

$ cleanup:
$       save_ver = f$verify('save_ver')


tta rv  Wednesday 23-JUN-1993 14:17