Conference iosg::all-in-1_v30

    In V3.0, you can use IA (Index of Attachments) and just select and
    print the ones you want.
    
    Otherwise it would "be a simple customisation" to add functionality to
    print only the last attachment :-)
    
    Graham

!+
! Increment only in V3.0, use compute if previous versions!
!-
.IF OA$FORM_NAME == "OA$LIST" THEN {KEY 0}

.FX GET OA$SCRIPT_EXIT_HANDLER = ""
.FX CAB CURRENT OA$SCROLL_KEY
.FX GET #LAST = 0
.FX FOR CAB$ATTACH DO GET #LAST = .%COUNT


.IF #LAST == 0 THEN .GOTO READ

.FX GET #A = 0
.FX FOR CAB$ATTACH DO INCREMENT(#A) \\ -
    .IF #A == #LAST THEN GET #LAST_KEY = .VALUE 


.FX TEXT_FILE OPEN ATTACH #LAST_KEY 
.FX TEXT_FILE READ ATTACH #LINE
!+
! Might need to cope with blank lines preceding first VMSmail text...
!-
.IF #LINE CONTAINING "VMSmail" THEN .FX COMPUTE #LAST = #LAST - 1 
.FX TEXT_FILE CLOSE ATTACH

.FX GET #A = 0
.FX FOR CAB$ATTACH DO -
  INCREMENT(#A) \\-
  .IF #A == #LAST THEN -
       GET #CURATTACH = .VALUE \\\\-
       GET #FC_FILENAME = OA$DIR_PARSE:"*.*".NAME[.VALUE] \\\\-
       GET #FC_DTITLE = CAB$ATTACH_ATTRIBUTES.VALUE["DTITLE"]

.FX GET #A = 0
.FX FOR CAB$ATTACH DO INCREMENT(#A) \\ .IF #A == #LAST THEN -
 .IF CAB$ATTACH_ATTRIBUTES.VALUE["DTYPE"] NES OA$MAIL_TYPE -
  THEN .FX GET OA$FUNCTION = "LIST " .VALUE -
  ELSE .FX LIST <MERGE MAILATT2 

.FX CLOSE_PRIOR
.FX OA$LIST_EXIT
.FX OA$LIST_REFRESH

.IF OA$CURDOC_FOLDER NES "INBOX" THEN .GOTO EXIT

.FX CAB CURRENT 
.IF OA$FORM_NAME CONTAINING "INDEX" THEN .FX CAB CURRENT OA$SCROLL_KEY
.FX GET #SAVE = OA$CURMES = OA$CURDOC
.FX MAIL DELETE/CLEAR/NOPROMPT
.FX OA$MSG_PURGE
.FX GET OA$CURMES = OA$WASTEBASKET:30 #SAVE:6:30 
.FX CAB CURRENT OA$CURMES

.FX CAB DELETE_OR_REFILE OA$CURDOC,"READ"

.IF OA$FORM_NAME CONTAINING "INDEX" THEN - 
  .FX OA$SCL_UPDATE CAB$.%ADDRESS[OA$CURDOC] 
.IF OA$FORM_NAME CONTAINING "INDEX" THEN - 
  .FX OA$SCL_REFRESH

.LABEL EXIT
.REFRESH
.EXIT

.LABEL READ
R{CR}

    
    Hi all.
    
    	I'm kinda new to ALL-IN-1, and have a problem with attachments 
    on documents.  
    
    I receive customer orders via all-in-1, sent from VAXmail.  I get 
    in the area of 100- 125 a day, all with attachments on them, the 
    attachment being a 2 line VMSmail header.  
    
    Now, I print these out in batches, and that 2 line attachment prints
    on a separate sheet.  Meaning, I get 1-2 extra sheets of paper
    for every order.  A lot of wasted paper.  
    
    I'm using A1 because of the relatively easy method of printing the
    orders.  I'd rather not have to go through 75 messages and file
    attachments elsewhere before I go to print.  
    
    Is there any way to do away with attachments, so they don't 
    print out, en masse?
    
    Any pointers/tips would be appreciated.
    
    
    thanks,
    
    /craig
    

    When you say VMSmail you mean I take it that the messages are entering
    ALL-IN-1 via MRGATE and if so you will find that note 280 will tell you how
    to solve this problem.
    
    Andrew.D.Wicks