Conference iosg::all-in-1_v30

        This is not an elegant one.  The form SFCS$CREATE.FLG is from
        Shared File Cabinet.  The key is that the /SCROLL qualifier
        points to a simple ENTRY form and that the fields in the scroll
        region have the same names as the fields in the ENTRY form.
        
        I will post it in the next reply as the .FLG is 290 lines long
        and it will make the DECwindows Notes users happier if they
        could skip over it.
        
        _Mike

 
!          FMS Form Description Application Aid 
!                     Version V2.3
 
FORM NAME='SFCS$CREATE'
    AREA_TO_CLEAR=7:23
    WIDTH=80
    BACKGROUND=CURRENT
    ;

SCROLL BEGIN_WITH=7  END_WITH=19 ;

TEXT (20,1) 'qqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqq'
    &'qqqqqqqqqqqqqqqqqqqq'
    CHARACTER_SET=RULE
    ;
TEXT (22,3) 'UP/DOWN '
    BOLD 
    ;
TEXT (22,11) '- Move'
    ;
TEXT (22,20) 'RETURN '
    BOLD 
    ;
TEXT (22,27) '- Enter'
    ;
TEXT (22,37) 'GOLD FILE '
    BOLD 
    ;
TEXT (22,47) '- Finish(Save)'
    ;
TEXT (22,64) 'EXIT '
    BOLD 
    ;
TEXT (22,69) '- Cancel'
    ;

ATTRIBUTE_DEFAULTS FIELD
    CLEAR_CHARACTER=' '
    NOAUTOTAB BLANK_FILL NOBLINKING NOBOLD NOREVERSE
    NOUNDERLINE NODISPLAY_ONLY ECHO NOFIXED_DECIMAL
    LEFT_JUSTIFIED NOSUPERVISOR_ONLY NOSUPPRESS NOUPPERCASE
    ;

FIELD NAME='SCROLL_KEY'  (7,1)
    PICTURE=5'X'
    NOECHO DISPLAY_ONLY 
    ;
FIELD NAME='USER'  (7,6)
    PICTURE=30'X'
    UPPERCASE 
    ;
FIELD NAME='VMSUSR'  (7,37)
    PICTURE=12'X'
    DISPLAY_ONLY 
    ;
FIELD NAME='READ'  (7,52)
    PICTURE='X'
    UPPERCASE 
    ;
FIELD NAME='MODIFY_DOCUMENT'  (7,60)
    PICTURE='X'
    UPPERCASE 
    ;
FIELD NAME='MODIFY_INDEX'  (7,68)
    PICTURE='X'
    UPPERCASE 
    ;
FIELD NAME='CONTROL'  (7,76)
    PICTURE='X'
    AUTOTAB UPPERCASE 
    ;

ORDER BEGIN_WITH = 1
    NAME='SCROLL_KEY' 
    NAME='USER' 
    NAME='VMSUSR' 
    NAME='READ' 
    NAME='MODIFY_DOCUMENT' 
    NAME='MODIFY_INDEX' 
    NAME='CONTROL' 
    ;

NAMED_DATA INDEX=1 NAME='.TYPE'
    DATA='ARG /PRE = ''XOP "~~START~~"\GET #REC_COUNT= "1"\GET #VALID_USER = 0' ;
NAMED_DATA INDEX=2 NAME='.TYPE'
    DATA='\GET #SFC_FORM_TERM = 0\get #read = oa$yes:1' ;
NAMED_DATA INDEX=3 NAME='.TYPE'
    DATA='\get #mod_index=#mod_document=#control= oa$no:1''' ;
NAMED_DATA INDEX=4 NAME='.TYPE'
    DATA='/POST = ''.IF #TERM EQ 1 AND #SFC_FORM_TERM NE 0 THEN XOP "~~WRITE_SFC_SAC~~"''' ;
NAMED_DATA INDEX=5 NAME='SFC_NAME'
    DATA='/GET = #SFC_NAME' ;
NAMED_DATA INDEX=6 NAME='SCROLL_KEY'
    DATA='/GET = #REC_COUNT' ;
NAMED_DATA INDEX=7 NAME='SCROLL_KEY'
    DATA='/scroll=,,,SFC_SAC_TEMP' ;
NAMED_DATA INDEX=8 NAME='USER'
    DATA='/RECOG=PROFIL.USER/SHOW=VMSUSR/USE_FORM = SFCM$INDEX$AUTO' ;
NAMED_DATA INDEX=9 NAME='USER'
    DATA='/PUT_SAVE=#SFC_SC_RECORD_USER/HARD="ALL-IN-1 User Name"' ;
NAMED_DATA INDEX=10 NAME='USER'
    DATA='/VALID = <XOP "~~VALID_USER~~"' ;
NAMED_DATA INDEX=11 NAME='READ'
    DATA='/GET = OA$YES:1' ;
NAMED_DATA INDEX=12 NAME='READ'
    DATA='/VALID=OA$YN;CLOSE_PRIOR\' ;
NAMED_DATA INDEX=13 NAME='READ'
    DATA='.IF MODIFY_DOCUMENT EQS OA$Y AND READ EQS OA$N THEN' ;
NAMED_DATA INDEX=14 NAME='READ'
    DATA='  PUT_FIELD MODIFY_DOCUMENT,OA$N' ;
NAMED_DATA INDEX=15 NAME='READ'
    DATA='/HARD=''Read''' ;
NAMED_DATA INDEX=16 NAME='MODIFY_DOCUMENT'
    DATA='/GET = OA$NO:1' ;
NAMED_DATA INDEX=17 NAME='MODIFY_DOCUMENT'
    DATA='/VALID=<.IF MODIFY_DOCUMENT EQS OA$YES:1 THEN PUT_FIELD  READ,OA$YES:1\\' ;
NAMED_DATA INDEX=18 NAME='MODIFY_DOCUMENT'
    DATA=' OA$VAL_SET_VALID ELSE .IF MODIFY_DOCUMENT EQS OA$NO:1 THEN OA$VAL_SET_VALID' ;
NAMED_DATA INDEX=19 NAME='MODIFY_DOCUMENT'
    DATA='/HARD="Modify Document"' ;
NAMED_DATA INDEX=20 NAME='MODIFY_INDEX'
    DATA='/GET = OA$NO:1' ;
NAMED_DATA INDEX=21 NAME='MODIFY_INDEX'
    DATA='/VALID=OA$YN/HARD="Modify Index"' ;
NAMED_DATA INDEX=22 NAME='CONTROL'
    DATA='/GET = OA$NO:1' ;
NAMED_DATA INDEX=23 NAME='CONTROL'
    DATA='/VALID=OA$YN/HARD="Control"' ;
NAMED_DATA INDEX=24 NAME='~~START~~'
    DATA='.FX create sfc_sac_temp\' ;
NAMED_DATA INDEX=25 NAME='~~START~~'
    DATA='dump sfc_sac_temp\' ;
NAMED_DATA INDEX=26 NAME='~~START~~'
    DATA='OA$SCL_INIT,,,SFC_SAC_TEMP' ;
NAMED_DATA INDEX=27 NAME='~~DEFAULT_VALUES~~'
    DATA='put_field read,#read\put_field modify_document,#mod_document' ;
NAMED_DATA INDEX=28 NAME='~~DEFAULT_VALUES~~'
    DATA=' \put_field modify_index,#mod_index\put_field control,#control' ;
NAMED_DATA INDEX=29 NAME='~~POPULATE_VALUES~~'
    DATA='GET #READ = READ\GET #MOD_DOCUMENT =MODIFY_DOCUMENT\GET #MOD_INDEX=' ;
NAMED_DATA INDEX=30 NAME='~~POPULATE_VALUES~~'
    DATA='MODIFY_INDEX\GET #CONTROL = CONTROL' ;
NAMED_DATA INDEX=31 NAME='.GOLD F'
    DATA='.if user eqs "" and oa$scroll_key:z eqs #rec_count then ' ;
NAMED_DATA INDEX=32 NAME='.GOLD F'
    DATA='GET #SFC_FORM_TERM = 1\\GET #TERM =1\\oa$fld_scroll_off\\OA$FLD_EXIT else ' ;
NAMED_DATA INDEX=33 NAME='.GOLD F'
    DATA='GET #SFC_FORM_TERM = 1\\get #term = 1\\oa$fld_scroll_off\\oa$fld_done' ;
NAMED_DATA INDEX=34 NAME='.KEY 0'
    DATA='OA$FLD_SCROLL_OFF\OA$FLD_EXIT' ;
NAMED_DATA INDEX=35 NAME='.CR'
    DATA='GET #VALID = 0\XOP "~~RETURN_PRESSED~~"' ;
NAMED_DATA INDEX=36 NAME='.ENTER'
    DATA='.IF OA$SCROLL_KEY:Z < #REC_COUNT THEN OA$SCL_DOWN' ;
NAMED_DATA INDEX=37 NAME='.DOWN'
    DATA='.IF OA$SCROLL_KEY:Z < #REC_COUNT THEN OA$SCL_DOWN' ;
NAMED_DATA INDEX=38 NAME='~~RETURN_PRESSED~~'
    DATA='XOP "~~VALID_LINE~~"\' ;
NAMED_DATA INDEX=39 NAME='~~RETURN_PRESSED~~'
    DATA='.IF #VALID = 1 THEN XOP "~~INCREMENT_RECCOUNT~~"' ;
NAMED_DATA INDEX=40 NAME='~~RETURN_PRESSED~~'
    DATA='\\XOP "~~POPULATE_VALUES~~"' ;
NAMED_DATA INDEX=41 NAME='~~RETURN_PRESSED~~'
    DATA='\\OA$FRM_SET_FIELD SCROLL_KEY' ;
NAMED_DATA INDEX=42 NAME='~~RETURN_PRESSED~~'
    DATA='\\XOP "~~MOVE_SCROLL~~"' ;
NAMED_DATA INDEX=43 NAME='~~RETURN_PRESSED~~'
    DATA='\\PUT_FIELD SCROLL_KEY,#REC_COUNT' ;
NAMED_DATA INDEX=44 NAME='~~RETURN_PRESSED~~'
    DATA='\\XOP "~~DEFAULT_VALUES~~"\\' ;
NAMED_DATA INDEX=45 NAME='~~RETURN_PRESSED~~'
    DATA='OA$FRM_SET_FIELD USER\\GET #VALID=0\\GET #VALID_USER=0' ;
NAMED_DATA INDEX=46 NAME='~~INCREMENT_RECCOUNT~~'
    DATA='DECIMAL=I\COMPUTE  #REC_COUNT = #REC_COUNT + 1' ;
NAMED_DATA INDEX=47 NAME='~~VALID_LINE~~'
    DATA='XOP "~~USER_VALIDATION~~"\' ;
NAMED_DATA INDEX=48 NAME='~~VALID_LINE~~'
    DATA='.IF (READ = OA$YES:1 OR READ = OA$NO:1) AND' ;
NAMED_DATA INDEX=49 NAME='~~VALID_LINE~~'
    DATA='    (MODIFY_DOCUMENT = OA$YES:1 OR MODIFY_DOCUMENT = OA$NO:1) AND ' ;
NAMED_DATA INDEX=50 NAME='~~VALID_LINE~~'
    DATA='    (MODIFY_INDEX = OA$YES:1 OR MODIFY_INDEX = OA$NO:1) AND ' ;
NAMED_DATA INDEX=51 NAME='~~VALID_LINE~~'
    DATA='    (CONTROL = OA$YES:1 OR CONTROL = OA$NO:1) AND #VALID_USER = 1 THEN ' ;
NAMED_DATA INDEX=52 NAME='~~VALID_LINE~~'
    DATA='  GET #VALID = 1\' ;
NAMED_DATA INDEX=53 NAME='~~VALID_LINE~~'
    DATA='.IF (READ == OA$N AND MODIFY_DOCUMENT == OA$Y) THEN' ;
NAMED_DATA INDEX=54 NAME='~~VALID_LINE~~'
    DATA='  GET #VALID = 0\\' ;
NAMED_DATA INDEX=55 NAME='~~VALID_LINE~~'
    DATA='  GET #SFCP_LAST_ERROR = "SFCP_INVALID_PRIVS"\\' ;
NAMED_DATA INDEX=56 NAME='~~VALID_LINE~~'
    DATA='  GET OA$DISPLAY = SFCP$MESSAGE.TEXT[#SFCP_LAST_ERROR]\\' ;
NAMED_DATA INDEX=57 NAME='~~VALID_LINE~~'
    DATA='  FORCE' ;
NAMED_DATA INDEX=58 NAME='~~WRITE_SFC_SAC~~'
    DATA='DUMP SFC_SAC_TEMP' ;
NAMED_DATA INDEX=59 NAME='~~WRITE_SFC_SAC~~'
    DATA='\FOR SFC_SAC_TEMP DO .fx  ' ;
NAMED_DATA INDEX=60 NAME='~~WRITE_SFC_SAC~~'
    DATA='.IF .USER NES "" THEN ' ;
NAMED_DATA INDEX=61 NAME='~~WRITE_SFC_SAC~~'
    DATA='WRITE ADD SFC_SAC  ' ;
NAMED_DATA INDEX=62 NAME='~~WRITE_SFC_SAC~~'
    DATA='USER=.USER, ' ;
NAMED_DATA INDEX=63 NAME='~~WRITE_SFC_SAC~~'
    DATA='VMSUSR=.VMSUSR,  ' ;
NAMED_DATA INDEX=64 NAME='~~WRITE_SFC_SAC~~'
    DATA='READ=.READ, ' ;
NAMED_DATA INDEX=65 NAME='~~WRITE_SFC_SAC~~'
    DATA='MODIFY_DOCUMENT=.MODIFY_DOCUMENT,  ' ;
NAMED_DATA INDEX=66 NAME='~~WRITE_SFC_SAC~~'
    DATA='MODIFY_INDEX=.MODIFY_INDEX, ' ;
NAMED_DATA INDEX=67 NAME='~~WRITE_SFC_SAC~~'
    DATA='CONTROL=.CONTROL' ;
NAMED_DATA INDEX=68 NAME='~~WRITE_SFC_SAC~~'
    DATA='\\GET #SFC_CHANGE_ACCESS = "1"' ;
NAMED_DATA INDEX=69 NAME='~~WRITE_SFC_SAC~~'
    DATA='\DUMP SFC_SAC' ;
NAMED_DATA INDEX=70 NAME='~~VALID_USER~~'
    DATA='XOP "~~USER_VALIDATION~~"\' ;
NAMED_DATA INDEX=71 NAME='~~VALID_USER~~'
    DATA='.IF #VALID_USER EQS "1" THEN GET #VALID_USER = 0\\PUT_FIELD VMSUSR,#VMSUSR' ;
NAMED_DATA INDEX=72 NAME='~~VALID_USER~~'
    DATA='\\OA$VAL_SET_VALID' ;
NAMED_DATA INDEX=73 NAME='~~NO_SUCH_PERSON~~'
    DATA='GET #SFCP_LAST_ERROR = "SFCP_NO_PROFILE"\' ;
NAMED_DATA INDEX=74 NAME='~~NO_SUCH_PERSON~~'
    DATA='GET OA$DISPLAY = SFCP$MESSAGE.TEXT[#SFCP_LAST_ERROR]\force' ;
NAMED_DATA INDEX=75 NAME='~~NOT_ID_VALID~~'
    DATA='GET #SFCP_LAST_ERROR = "SFCP_INV_USER_VMS_ID_CREATE"\' ;
NAMED_DATA INDEX=76 NAME='~~NOT_ID_VALID~~'
    DATA='GET OA$DISPLAY = SFCP$MESSAGE.TEXT[#SFCP_LAST_ERROR]\force' ;
NAMED_DATA INDEX=77 NAME='~~USER_THERE~~'
    DATA='GET #SFCP_LAST_ERROR = "SFCP_USER_AUTHORISE"\' ;
NAMED_DATA INDEX=78 NAME='~~USER_THERE~~'
    DATA='GET OA$DISPLAY = SFCP$MESSAGE.TEXT[#SFCP_LAST_ERROR]\force' ;
NAMED_DATA INDEX=79 NAME='~~USER_IN_CURRENT~~'
    DATA='GET #SFCP_LAST_ERROR = "SFCP_USER_IN_CURRENT_BLOCK"\' ;
NAMED_DATA INDEX=80 NAME='~~USER_IN_CURRENT~~'
    DATA='GET OA$DISPLAY = SFCP$MESSAGE.TEXT[#SFCP_LAST_ERROR] \force' ;
NAMED_DATA INDEX=81 NAME='~~NO_PROFIL_VMSUSR~~'
    DATA='GET #SFCP_LAST_ERROR = "SFCP_MAINT_NO_VMS_ACCOUNT"\' ;
NAMED_DATA INDEX=82 NAME='~~NO_PROFIL_VMSUSR~~'
    DATA='GET OA$DISPLAY = SFCP$MESSAGE.TEXT[#SFCP_LAST_ERROR] \force' ;
NAMED_DATA INDEX=83 NAME='~~USER_VALIDATION~~'
    DATA=' GET #VALID_USER = 0\' ;
NAMED_DATA INDEX=84 NAME='~~USER_VALIDATION~~'
    DATA=' GET #SFC_ID_VALID = "0"\' ;
NAMED_DATA INDEX=85 NAME='~~USER_VALIDATION~~'
    DATA='.IF PROFIL.VMSUSR[USER] NES "" THEN ' ;
NAMED_DATA INDEX=86 NAME='~~USER_VALIDATION~~'
    DATA='  GET VMSUSR = #VMSUSR = PROFIL.VMSUSR[USER]\\' ;
NAMED_DATA INDEX=87 NAME='~~USER_VALIDATION~~'
    DATA='  SFC_CHECK_ID #VMSUSR\\GET #SFC_ID_VALID = OA$STATUS\' ;
NAMED_DATA INDEX=88 NAME='~~USER_VALIDATION~~'
    DATA=' .IF USER EQS "" THEN GET #VALID_USER=0\\XOP "~~NO_SUCH_PERSON~~"' ;
NAMED_DATA INDEX=89 NAME='~~USER_VALIDATION~~'
    DATA='  ELSE ' ;
NAMED_DATA INDEX=90 NAME='~~USER_VALIDATION~~'
    DATA=' .IF USER EQS SFC_SAC_TEMP:USER.USER[USER] AND OA$SCROLL_KEY:Z NES ' ;
NAMED_DATA INDEX=91 NAME='~~USER_VALIDATION~~'
    DATA=' SFC_SAC_TEMP:USER.SCROLL_KEY[USER] THEN XOP "~~USER_IN_CURRENT~~" ' ;
NAMED_DATA INDEX=92 NAME='~~USER_VALIDATION~~'
    DATA='  ELSE' ;
NAMED_DATA INDEX=93 NAME='~~USER_VALIDATION~~'
    DATA=' .IF PROFIL.USER[USER] EQS "" THEN XOP "~~NO_SUCH_PERSON~~" ' ;
NAMED_DATA INDEX=94 NAME='~~USER_VALIDATION~~'
    DATA='  ELSE' ;
NAMED_DATA INDEX=95 NAME='~~USER_VALIDATION~~'
    DATA=' .IF PROFIL.VMSUSR[USER] EQS "" THEN XOP "~~NO_PROFIL_VMSUSR~~" ' ;
NAMED_DATA INDEX=96 NAME='~~USER_VALIDATION~~'
    DATA='  ELSE ' ;
NAMED_DATA INDEX=97 NAME='~~USER_VALIDATION~~'
    DATA=' .IF SFC_SAC:USER.USER[USER] NES "" THEN XOP "~~USER_THERE~~" ' ;
NAMED_DATA INDEX=98 NAME='~~USER_VALIDATION~~'
    DATA='  ELSE  ' ;
NAMED_DATA INDEX=99 NAME='~~USER_VALIDATION~~'
    DATA=' .IF #SFC_ID_VALID EQS "0" THEN XOP "~~NOT_ID_VALID~~"' ;
NAMED_DATA INDEX=100 NAME='~~USER_VALIDATION~~'
    DATA='  ELSE ' ;
NAMED_DATA INDEX=101 NAME='~~USER_VALIDATION~~'
    DATA=' GET #VALID_USER = 1' ;
NAMED_DATA INDEX=102 NAME='~~MOVE_SCROLL~~'
    DATA='.IF OA$SCROLL_KEY:Z < #REC_COUNT THEN OA$SCL_DOWN\\XOP "~~MOVE_SCROLL~~" ' ;
 
END_OF_FORM NAME='SFCS$CREATE' ;
        

    In V3 the forms used to enter ACLs, on drawers for example, contain
    multi-field scrolled regions. They are however dependent on V3
    functionality.
    
    Cheers
    
    Stuart