| Hi there!
> The first one is, is there a way to completely shutdown ALL-IN-1 other
> than the menu option of SDA? And then to be able to start it up.
If you follow the named data for SDA, you will see it calls the
ALL-IN-1 "SHUTDOWN" function, which does the business. Its documented
in the Application Programming Reference, vol 2, page 546.
> When you do SDA it seems that only a logical is being redefined which
> prohibits logins, but all the images are still running?
That is not quite the whole story. In addition to setting the "logical"
(its a system PST symbol actually) it takes out a VMS lock which
signals all the running processes that they should exit. If you wait
a few minutes, you will see all the images exit (except yours).
Shutdown in V3.0 and V2.4 with the TeamLinks Connection Package has
changed, in that you need to shutdown the FileCab servers as well,
so its not just as simple as calling SHUTDOWN. Look at the SDA option
on your V3.0 system.
> The reason for this line of questioning is, the customer wants to do a
> complete backup without having any files open.
By all means use SHUTDOWN to kick off your users, but I think you
need to reinforce it with some VMS DCL in case the users have files
open other than from ALL-IN-1, or in case shutdown goes wrong somehow.
I hope this isn't the system disk you are trying to back up. No, I
thought not.
> The final question is what does SMJACKET.SCP and SMJACKET.COM perform?
>
> We are seeing these refered to in a couple of the housekeeping log
> files.
They are standard routines that run at the start of every houskeeping
procedure and check privileges and protections and things. They also
do automatic rescheduling of housekeeping procedures etc. Take a peek
if you're curious.
Regards,
Paul
|
| Shutting down ALL-IN-1 for backing up disks requires
that the files are closed on those disks.
Because ALL-IN-1 keeps e.g. compiled form libraries
installed into memory, you cannot have the respective
files closed before they are de-installed from mermory
SDA menu command nor the shutdown function does this,
you have to do it manually or write a procedure.
Quite complete instructions may be found from a TIMA/STARS
article (header below), but remember to check also
Form libraries of assets or applications in addition the
normal ones mentioned in article.
Article Header Information Display
Article: 2916 Database: OA1
Identifier: 00935A2C-57734760-1C0125
Title: Cannot Dismount Disk after BACKUP/IGNORE, ALL-IN-1 Locks Fil
Author: 999994 ENGINEERING 10-APR-1990
Enter: 140177 PROHASKA 23-APR-1990
Modify: 204951 DAVE ZANIEWSKI 24-APR-1990
Edit Review: 035873 KC CABRAL 10-APR-1990
Tech Review: 169759 FAITH DONOHUE 24-APR-1990
Expiration: 7-MAY-1992 Flash: (no date)
Geography: USA Site: ALF1 Owner: OA1
Message:
Flags: Edit. Review USA Cust. Read. Field Readable
Tech. Review EUR Cust. Read. Not Disp. Msg. Befor
Ready GIA Cust. Read. Not Disp. Msg. After
Not Local Not Cust. Flash
Sys. Create: TIMA_MGR 26-APR-1990 20:29:11.55
Sys. Modify: TIMA_MGR 29-MAY-1991 06:26:33.82 Count: 3
Last Access: 24-MAR-1992 16:13:00.78 Last Clear: 29-MAY-1991 06:26:33.82
Accesses: Lifetime: 9 Current: 1
|
| Hi,
Has anyone written a command procedure to shut down ALL-IN-1? We
have a customer who wants to shut down ALL-IN-1 automatically before
their disk backups, and since the group that performs disk backups is
distinct from the group that manages ALL-IN-1...
The idea of a command procedure is so they can submit a batch job to
shut down ALL-IN-1 on a nightly basis, and then have it restart
automatically.
If anyone has done this, or has thoughts on special requirements,
please NOTE it!
Thanks in advance, Cheers, Dan'l
|
| I don't think its a problem backing up open ALL-IN-1 files
when ALL-IN-1 is Shutdown using SDA. No one is writing to
the files, so there is no risk loosing data.
But, when the customer insists, this STARS article is a good start.
Cannot Dismount Disk after BACKUP/IGNORE, ALL-IN-1 Locks Files
COPYRIGHT (c) 1988, 1989, 1990 by Digital Equipment Corporation.
ALL RIGHTS RESERVED. No distribution except as provided under contract.
PRODUCT: ALL-IN-1 V2.3
OP/SYS: VAX/VMS V5.2
SOURCE: Customer Support Center/Atlanta USA
QUESTION:
You would like to periodically use disk-to-disk BACKUP to
defragment the disk that ALL-IN-1 files reside on. Currently,
after you finish using BACKUP/IGNORE=INTERLOCK, you cannot
dismount the disk because many PIDs still have various ALL-IN-1
files locked.
Is there a method for ALL-IN-1 and ALL-IN-1 users to release all
access to files on a system (also in a cluster environment)?
ANSWER:
The SHUTDOWN operation is intended to dislodge ALL-IN-1 users by
warning them of the shutdown and eventually forcing image exit.
This operation is intended for housekeeping purposes so that
operations on the ALL-IN-1 system and file cabinets can be
performed without needing further interlocks or controls on
access. For this reason, the ALL-IN-1 system is left in a state
that allows such housekeeping procedures to run (using the
/OVERRIDE_SHUTDOWN qualifier).
If you wish to dismount the disk containing the ALL-IN-1 system,
after the ALL-IN-1 system has been shutdown, you must perform a
number of additional operations to close open files on the disk.
Perform the following operations:
- Remove the Form Library (FLC) global sections using the
OA$FBT_REMOVE_LIBRARY function:
$ ALLIN1/NOINIT/OVERRIDE
OA$FBT_REMOVE_LIBRARY OA$LIB:MEMRES
OA$FBT_REMOVE_LIBRARY OA$LIB:OAFORM
OA$FBT_REMOVE_LIBRARY OA$LIB:SITEMEMRES
OA$FBT_REMOVE_LIBRARY OA$LIB:SITEOAFORM
- Remove the Text Library (TXL) global sections (A1TXL
and CMTXL) using the OA$TXL_REMOVE function:
$ ALLIN1/NOINIT/OVERRIDE
OA$TXL_REMOVE A1TXL
OA$TXL_REMOVE CMTXL
- Remove the image global sections (MAILCOUNT, OA$SUBMIT,
TMSV, OAFCV and OA$MAIN) using the VAX/VMS INSTALL
utility:
$ INSTALL == "$SYS$SYSTEM:INSTALL /COMMAND_MODE"
$ INSTALL
REMOVE OA$LIB:MAILCOUNT
REMOVE OA$LIB:OA$SUBMIT
REMOVE OA$LIB:TMSV
REMOVE OA$LIB:OAFCV
REMOVE OA$LIB:OA$MAIN
- Shut down the background processes using the appropriate
DCL commands:
$ STOP/QUEUE/NEXT OA$FORMATTER
$ STOP TM_SERVER
$ STOP OA$FCV
$ STOP/QUEUE/NEXT OA$MTI_QUEUE !For SENDER/FETCHER
!Also STOP any other batch
!queues used for housekeeping
!jobs
- Shut down MAILBUS processes if installed/running on the
disk (note: All components which are running on your system).
Ex:
$@SYS$MANAGER:MB$CONTROL STOP=(ER,DDS,MRG,TS,MS)
- Shut down print queues which may be accessing formatted
files on the disk.
- Perform similar shutdown operations on each node in the
cluster.
Because this operation needs to be performed for each node in a
cluster, you may wish to construct a command procedure to perform
these commands, then use the VAX/VMS SYSMAN utility to execute the
procedure on all nodes in the cluster, or as an alternative submit the
procedure into batch queues for each node.
We acknowledge that the ALL-IN-1 system environment is sufficiently
complex to warrant a procedure to allow the system manager to shut
down the product completely. We will investigate such a procedure
for inclusion in a future major release of the ALL-IN-1 product.
You may also wish to investigate the use of the DCL DISMOUNT command
qualifier /ABORT as a means of dismounting the disk irrespective of
accessors.
Below, is an example command procedure used to completely shutdown
ALL-IN-1 on a system. This may require customizations for your specific
system configuration, but may be used as a template.
$! Shut down ALL-IN-1 2 minutes from now
$now=f$time()
$soon_time="''now' +:2"
$soon=f$cvtime(soon_time)
$!
$! Convert it back to a format ALL-IN-1 can use
$!
$year=f$extract(0,4,soon)
$month=f$extract(5,2,soon)
$day=f$extract(8,2,soon)
$hour_min=f$extract(11,5,soon)
$if month .eqs. "01" then mm="JAN"
$if month .eqs. "02" then mm="FEB"
$if month .eqs. "03" then mm="MAR"
$if month .eqs. "04" then mm="APR"
$if month .eqs. "05" then mm="MAY"
$if month .eqs. "06" then mm="JUN"
$if month .eqs. "07" then mm="JUL"
$if month .eqs. "08" then mm="AUG"
$if month .eqs. "09" then mm="SEP"
$if month .eqs. "10" then mm="OCT"
$if month .eqs. "11" then mm="NOV"
$if month .eqs. "12" then mm="DEC"
$new_soon_time="''day'-''mm'-''year' ''hour_min'"
$!
$! Enter ALL-IN-1 and do the shutdown
$!
$allin1/user=manager/override/noinit
oa$ini_init
get #when=cli$new_soon_time
get #why="Dismounting ALL-IN-1 disks"
shutdown #when, #why
exit
$! Stop the sender and fetcher batch jobs
$stop/queue/next oa$mti_queue
$! Stop the TM server
$stop tm_server
$! Stop the file namer
$stop oa$fcv
$! Shut down mailbus
$@sys$manager:mb$control stop=(er,dds,mrg,ts,ms)
$! Stop the formatter queue
$stop/queue/next oa$formatter
$! Stop other print queues
$!
$! Remove form libraries and TXL's
$allin1/noinit/override
oa$fbt_remove_library oa$lib:memres
oa$fbt_remove_library oa$lib:oaform
oa$fbt_remove_library oa$lib:sitememres
oa$fbt_remove_library oa$lib:siteoaform
oa$txl_remove a1txl
oa$txl_remove cmtxl
exit
$! Remove installed images
$! Some of these will produce warning messages,
$! because they are not part of the A1V23START
$! but are necessary after a relink without reboot
$install:=="$sys$system:install /command_mode"
$install
remove oa$lib:mailcount
remove oa$lib:oa$submit
remove oa$lib:tmsv
remove oa$lib:oafcv
remove oa$lib:oa$main
$!
$exit
|